synfig-core/trunk/configure.ac

   1 # $Id$
   2
   3 # -- I N I T --------------------------------------------------
   4
   5 AC_INIT([Synfig Core],[0.61.09],[http://synfig.org/Bugs],[synfig])
   6 AC_REVISION
   7
   8 AC_CONFIG_AUX_DIR(config)
   9 AC_CONFIG_HEADERS([config.h])
  10 AC_CANONICAL_HOST
  11 dnl AC_CANONICAL_TARGET
  12
  13 AM_INIT_AUTOMAKE([nostdinc])
  14 AM_MAINTAINER_MODE
  15
  16 AC_LIBLTDL_CONVENIENCE
  17 AC_SUBST(INCLTDL)
  18 AC_SUBST(LIBLTDL)
  19
  20 API_VERSION=0.0
  21
  22
  23 AC_DEFINE(LT_SCOPE,[extern],[LibLTDL is linked staticly])
  24
  25
  26
  27
  28 # -- V A R I A B L E S ----------------------------------------
  29
  30 SVN_REPOSITORY=https://synfig.svn.sourceforge.net/svnroot/synfig/synfig-core
  31 AC_SUBST(SVN_REPOSITORY)
  32
  33 AC_C_BIGENDIAN
  34
  35 # -- P R O G R A M S ------------------------------------------
  36
  37 AC_PROG_CC
  38 AC_GNU_SOURCE
  39 AC_PROG_CXX
  40 AC_PROG_CPP
  41 AC_PROG_CXXCPP
  42 AC_PROG_INSTALL
  43
  44 AC_LANG([C++])
  45
  46
  47 # -- A R G U M E N T S ----------------------------------------
  48
  49
  50 AC_ARG_DEBUG
  51 AC_ARG_OPTIMIZATION
  52 AC_ARG_WARNINGS
  53 AC_ARG_PROFILING
  54 AC_ARG_PROFILE_ARCS
  55 AC_ARG_BRANCH_PROBABILITIES
  56
  57 AC_ARG_ENABLE(g5opt,[
  58   --enable-g5opt           enable optimizations specific to G5 proc],[
  59 #       CXXFLAGS="$CXXFLAGS -fastf -fPIC"
  60 #       CFLAGS="$CFLAGS -fastf -fPIC"
  61         CXXFLAGS="$CXXFLAGS -mtune=G5 -falign-loops=32"
  62         CFLAGS="$CFLAGS -mtune=G5"
  63 ],
  64 [
  65         true
  66 ])
  67
  68 #MINGW_FLAGS="-mno-cygwin"
  69
  70 AC_WIN32_QUIRKS
  71
  72 # If we are in debug mode, use the debugging version of the
  73 # Microsoft Visual C Runtime Library
  74 #if [[ $debug = "yes" ]] ; then {
  75 #       WIN32_DEBUG_LIBRARY="msvcr70d"
  76 #       WIN32_DEBUG_LIBRARY="msvcrtd"
  77 #       LIBTOOL_PATCH_SED="$LIBTOOL_PATCH_SED
  78 #               s/-lmsvcrt/-l$WIN32_DEBUG_LIBRARY/g;
  79 #       ";
  80 #} ; fi
  81
  82 AC_LIBTOOL_WIN32_DLL
  83 AC_LIBTOOL_DLOPEN
  84 AC_DISABLE_STATIC
  85 AC_ENABLE_SHARED
  86 AC_PROG_LIBTOOL
  87 AC_SUBST(LIBTOOL_DEPS)
  88 AC_LIBTOOL_PATCH
  89
  90 #if [[ "$LIBTOOL_PATCH_SED""x" != "x" ]] ; then {
  91 #       printf "Patching libtool... "
  92 #       cat libtool | sed "$LIBTOOL_PATCH_SED" > libtool2
  93 #       rm libtool
  94 #       mv libtool2 libtool
  95 #       chmod +x libtool
  96 #       AC_MSG_RESULT([patched])
  97 #} fi ;
  98
  99
 100 dnl
 101 dnl dynamic linker
 102 dnl
 103 AC_CHECK_LIB(c, dlopen,
 104         DYNAMIC_LD_LIBS="",
 105         AC_CHECK_LIB(
 106                 dl,
 107                 dlopen,
 108         DYNAMIC_LD_LIBS="-ldl",
 109             DYNAMIC_LD_LIBS=""
 110         )
 111 )
 112
 113 AC_SUBST(DYNAMIC_LD_LIBS)
 114
 115 AC_ARG_ENABLE(half,[
 116   --enable-half           Use OpenEXR's "half" type for color],[
 117         use_openexr_half=$enableval
 118 ],
 119 [
 120         use_openexr_half="no"
 121 ])
 122
 123
 124
 125 AC_ARG_ENABLE(layer-profiling,[
 126   --enable-layer-profiling       Enable layer profiling],[
 127         use_layerprofiling=$enableval
 128 ],
 129 [
 130         use_layerprofiling="no"
 131 ])
 132 if test $use_layerprofiling = "yes" ; then {
 133         AC_DEFINE(SYNFIG_PROFILE_LAYERS,[1],[enable layer profiling])
 134 } ; fi
 135
 136
 137
 138
 139 AC_ARG_WITH(imagemagick,[
 140   --without-imagemagick   Disable support for ImageMagick],[
 141 ],[
 142     AC_CHECK_PROG([imagemagick_convert],[convert],[yes],[no])
 143     with_imagemagick=$imagemagick_convert
 144 ])
 145 if test $with_imagemagick = "no" ; then {
 146         AM_CONDITIONAL(WITH_IMAGEMAGICK,false)
 147 } else {
 148         AM_CONDITIONAL(WITH_IMAGEMAGICK,true)
 149 } ; fi
 150
 151
 152
 153
 154
 155 AC_ARG_WITH(magickpp,[
 156   --without-magickpp        Disable support for Magick++],[
 157 ],[
 158         with_magickpp="yes"
 159 ])
 160 if test $with_magickpp = "yes" ; then {
 161   AC_CHECK_HEADER([Magick++.h],[
 162         MAGICKPP_LIBS="-lMagick++"
 163         AC_DEFINE(HAVE_MAGICKPP,[], [ Define if Magick++ library is available ] )
 164         AC_SUBST(MAGICKPP_LIBS)
 165         AM_CONDITIONAL(HAVE_LIBMAGICKPP,true)
 166         AC_CHECK_LIB(Magick,OptimizeImageTransparency,[
 167                 AC_DEFINE(HAVE_MAGICK_OPTIMIZE,[], [ Define if Magick++ defines OptimizeImageTransparency() ] )
 168                 AM_CONDITIONAL(HAVE_MAGICK_OPTIMIZE,true)
 169         ],[
 170                 AC_MSG_RESULT([ *** OptimizeImageTransparency() not available - need ImageMagick 6.3 or newer ])
 171                 AM_CONDITIONAL(HAVE_MAGICK_OPTIMIZE,false)
 172         ])
 173   ],[
 174         with_magickpp="no"
 175         AC_MSG_RESULT([ *** Magick++ Output target disabled])
 176         TARGET_MAGICKPP="no"
 177         AM_CONDITIONAL(HAVE_LIBMAGICKPP,false)
 178         AM_CONDITIONAL(HAVE_MAGICK_OPTIMIZE,false)
 179   ])
 180 } else {
 181         AM_CONDITIONAL(HAVE_LIBMAGICKPP,false)
 182         AM_CONDITIONAL(HAVE_MAGICK_OPTIMIZE,false)
 183 } ; fi
 184
 185
 186
 187
 188 AC_ARG_WITH(ffmpeg,[
 189   --without-ffmpeg        Disable support for FFMPEG],[
 190 ],[
 191         with_ffmpeg="yes"
 192 ])
 193 if test $with_ffmpeg = "no" ; then {
 194         AM_CONDITIONAL(WITH_FFMPEG,false)
 195 } else {
 196         AM_CONDITIONAL(WITH_FFMPEG,true)
 197 } ; fi
 198
 199
 200
 201
 202 AC_ARG_WITH(vimage,[
 203   --with-vimage        Enable support for apple vImage],[
 204 ],[
 205         with_vimage="no"
 206 ])
 207 if test $with_vimage = "no" ; then {
 208         AM_CONDITIONAL(WITH_VIMAGE,false)
 209 } else {
 210         AM_CONDITIONAL(WITH_VIMAGE,true)
 211         AC_DEFINE(HAS_VIMAGE,[1],[enable apple vImage])
 212         VIMAGE_LIBS="-Wc,-framework -Wc,Accelerate"
 213
 214 } ; fi
 215
 216
 217
 218 AC_ARG_WITH(libdv,[
 219   --without-libdv         Disable support for libdv],[
 220 ],[
 221         with_libdv="yes"
 222 ])
 223 if test $with_libdv = "no" ; then {
 224         AM_CONDITIONAL(WITH_LIBDV,false)
 225 } else {
 226         AM_CONDITIONAL(WITH_LIBDV,true)
 227 } ; fi
 228
 229
 230
 231
 232 # LIBAVCODEC CHECK--------------------
 233
 234 AC_ARG_WITH(libavcodec,[
 235   --without-libavcodec         disable support for libavcodec (Default=auto)],[
 236 ],[
 237         with_libavcodec="yes"
 238 ])
 239
 240 if test $with_libavcodec != "no" ; then {
 241         PKG_CHECK_MODULES(LIBAVCODEC, [libavcodec libavformat],[],[echo no; with_libavcodec="no"])
 242 } ; fi
 243 if test $with_libavcodec = "yes" ; then {
 244         AC_DEFINE(WITH_LIBAVCODEC,[],[enable libavcodec support])
 245         AM_CONDITIONAL(WITH_LIBAVCODEC,true)
 246 } else {
 247         AM_CONDITIONAL(WITH_LIBAVCODEC,false)
 248 } ; fi
 249
 250
 251 if test $with_libavcodec = "yes" ; then {
 252
 253         # Need to check both the new and old locations for the avformat header
 254         # Need to save flags, add avformat flags, check headers and restore flags
 255         ac_save_CPPFLAGS="$CPPFLAGS"
 256         ac_save_CFLAGS="$CFLAGS"
 257         CPPFLAGS="${CPPFLAGS} ${LIBAVCODEC_CFLAGS}"
 258         CFLAGS="${CFLAGS} ${LIBAVCODEC_CFLAGS}"
 259         AC_CHECK_HEADERS(libavformat/avformat.h avformat.h ffmpeg/avformat.h)
 260         CPPFLAGS="${ac_save_CPPFLAGS}"
 261         CFLAGS="${ac_save_CFLAGS}"
 262
 263         AC_ARG_WITH(libswscale,
 264                 [AS_HELP_STRING([--without-libswscale],
 265                         [disable support for libswscale (Default=auto)])],
 266                 [],
 267                 [with_libswscale="yes"]
 268         )
 269
 270         if test $with_libswscale != "no" ; then {
 271                 PKG_CHECK_MODULES(LIBSWSCALE, [libswscale], [], [echo no; with_libswscale="no"])
 272         } ; fi
 273
 274         if test $with_libswscale = "yes" ; then {
 275                 AC_DEFINE(WITH_LIBSWSCALE, [], [enable libswscale support])
 276
 277                 # Need to check both the new and old locations for the swscale header
 278                 # Need to save flags, add swscale flags, check headers and restore flags
 279                 ac_save_CPPFLAGS="$CPPFLAGS"
 280                 ac_save_CFLAGS="$CFLAGS"
 281                 CPPFLAGS="${CPPFLAGS} ${LIBSWSCALE_CFLAGS}"
 282                 CFLAGS="${CFLAGS} ${LIBSWSCALE_CFLAGS}"
 283                 AC_CHECK_HEADERS(libswscale/swscale.h swscale.h ffmpeg/swscale.h)
 284                 CPPFLAGS="${ac_save_CPPFLAGS}"
 285                 CFLAGS="${ac_save_CFLAGS}"
 286         } else {
 287                 AC_CHECK_LIB(avcodec, img_convert,
 288                         [AC_MSG_RESULT([ *** Using deprecated function img_convert.])],
 289                         [AC_MSG_FAILURE([Neither libswscale nor function img_convert was found.])],
 290                         []
 291                 )
 292         } ; fi
 293 } ; fi
 294 AM_CONDITIONAL(WITH_LIBSWSCALE, test "x$with_libswscale" = "xyes")
 295
 296
 297 # FREETYPE2 CHECK--------------------
 298
 299 AC_ARG_WITH(freetype,[
 300   --without-freetype         disable support for freetype (Default=auto)],[
 301 ],[
 302         with_freetype="yes"
 303 ])
 304
 305 if test $with_freetype != "no" ; then {
 306         PKG_CHECK_MODULES(FREETYPE, freetype2,[
 307                 with_freetype="yes"
 308         ],[
 309                 PKG_CHECK_MODULES(FREETYPE, xft,[
 310                         with_freetype="yes"
 311                 ],[
 312                         with_freetype="no"
 313                 ])
 314         ])
 315 } ; fi
 316
 317 if test $with_freetype = "no" ; then {
 318         AM_CONDITIONAL(WITH_FREETYPE,false)
 319 } else {
 320         AM_CONDITIONAL(WITH_FREETYPE,true)
 321 } ; fi
 322
 323
 324 # FONTCONFIG CHECK--------------------
 325
 326 AC_ARG_WITH(fontconfig,[
 327   --without-fontconfig         disable support for fontconfig (Default=auto)],[
 328 ],[
 329         with_fontconfig="yes"
 330 ])
 331
 332 if test $with_fontconfig != "no" ; then {
 333         PKG_CHECK_MODULES(FONTCONFIG, fontconfig,[
 334                 with_fontconfig="yes"
 335         ],[
 336                 with_fontconfig="no"
 337         ])
 338 } ; fi
 339
 340 if test $with_fontconfig = "yes" ; then {
 341         AC_DEFINE(WITH_FONTCONFIG,[],[enable fontconfig support])
 342         AM_CONDITIONAL(WITH_FONTCONFIG,true)
 343 } else {
 344         AM_CONDITIONAL(WITH_FONTCONFIG,false)
 345 } ; fi
 346
 347
 348 # OPENEXR CHECK------------------------
 349 AC_ARG_WITH(openexr,[
 350   --without-openexr        Disable support for ILM's OpenEXR],[
 351 ],[
 352         with_openexr="yes"
 353 ])
 354 if test $with_openexr = "yes" ; then {
 355         PKG_CHECK_MODULES(OPENEXR, OpenEXR,[
 356                 AC_DEFINE(HAVE_OPENEXR,[], [ Define if OpenEXR is available ] )
 357                 AM_CONDITIONAL(WITH_OPENEXR,true)
 358         ],
 359         [
 360                 with_openexr="no"
 361         ])
 362 } ; fi
 363 if test $with_openexr = "no" ; then {
 364         AM_CONDITIONAL(WITH_OPENEXR,false)
 365         use_openexr_half="no"
 366 } ; fi
 367 if test $use_openexr_half = yes ; then {
 368         AC_MSG_RESULT([ ** Using OpenEXR Half.])
 369         CONFIG_DEPS="$CONFIG_DEPS OpenEXR"
 370         CONFIG_CFLAGS="$CONFIG_CFLAGS -DUSE_HALF_TYPE"
 371         OPENEXR_HALF_LIBS="-lHalf"
 372 } else {
 373         OPENEXR_HALF_LIBS=""
 374 } ; fi
 375
 376
 377 # JPEG CHECK (commandline switch) ------------------------
 378 AC_ARG_WITH(jpeg,[
 379   --without-jpeg        Disable support for JPEG],[
 380 ],[
 381         with_jpeg="yes"
 382 ])
 383 if test $with_jpeg = "no" ; then {
 384         AM_CONDITIONAL(WITH_JPEG,false)
 385 } else {
 386         AM_CONDITIONAL(WITH_JPEG,true)
 387 } ; fi
 388
 389
 390
 391
 392
 393 # -- L I B R A R I E S ----------------------------------------
 394
 395 AC_LIB_LTDL
 396
 397 ALL_LINGUAS="es fr ru"
 398 AM_GNU_GETTEXT([external])
 399 # This is here so autoreconf will run autopoint
 400 AM_GNU_GETTEXT_VERSION([0.15])
 401 localedir="$datadir/locale"
 402
 403 PKG_CHECK_MODULES(ETL, [ETL >= 0.04.12],,[
 404         AC_MSG_ERROR([ ** You need to install the ETL (version 0.04.12 or greater).])
 405 ])
 406 CONFIG_DEPS="$CONFIG_DEPS ETL"
 407
 408
 409 PKG_CHECK_MODULES(LIBXMLPP, libxml++-2.6,[
 410         CONFIG_DEPS="$CONFIG_DEPS libxml++-2.6"
 411 ],[
 412         PKG_CHECK_MODULES(LIBXMLPP, libxml++-1.0,[
 413                 CONFIG_DEPS="$CONFIG_DEPS libxml++-1.0"
 414         ],[
 415                 AC_MSG_ERROR([ ** You need to install libxml++, either verison 2.6 or 1.0.])
 416         ])
 417 ])
 418
 419 PKG_CHECK_MODULES(LIBSIGC, [sigc++-2.0],,[
 420         AC_MSG_ERROR([ ** libsigc++-2.0 not found. It is required. You should really install it.])
 421 dnl     PKG_CHECK_MODULES(LIBSIGC, [sigc++-1.2],,[
 422 dnl             AC_MSG_ERROR([ ** At least libsigc++-1.2 is required.])
 423 dnl     ])
 424 ])
 425 CONFIG_DEPS="$CONFIG_DEPS sigc++-2.0"
 426
 427 dnl PKG_CHECK_MODULES(GLIB, glib-2.0,[GLIB="yes"],[GLIB="no"])
 428
 429
 430
 431
 432
 433 TARGET_PNG="yes"
 434 TARGET_MNG="yes"
 435
 436 AC_CHECK_LIB(png, png_write_row,[
 437         PNG_LIBS="-lpng"
 438         AC_DEFINE(HAVE_LIBPNG,[], [ Define if PNG library is available ] )
 439         AC_SUBST(PNG_LIBS)
 440         AM_CONDITIONAL(HAVE_LIBPNG,true)
 441 ],[
 442         AC_CHECK_LIB(png12, png_write_row,[
 443         PNG_LIBS="-lpng12"
 444         AC_DEFINE(HAVE_LIBPNG,[])
 445         AC_SUBST(PNG_LIBS)
 446         AM_CONDITIONAL(HAVE_LIBPNG,true)
 447         ],[
 448                 AC_MSG_RESULT([ *** PNG Output target disabled])
 449                 TARGET_PNG="no"
 450                 AM_CONDITIONAL(HAVE_LIBPNG,false)
 451         ],[-lz -L${exec_prefix}/lib])
 452 ],[-lz -L${exec_prefix}/lib])
 453
 454 AC_CHECK_LIB(mng, mng_initialize,[
 455         MNG_LIBS="-lmng -lz"
 456         AC_DEFINE(HAVE_LIBMNG,[], [ Define if MNG library is available ] )
 457         AC_SUBST(MNG_LIBS)
 458         AM_CONDITIONAL(HAVE_LIBMNG,true)
 459 ],[
 460         AC_MSG_RESULT([ *** MNG Output target disabled])
 461         TARGET_MNG="no"
 462         AM_CONDITIONAL(HAVE_LIBMNG,false)
 463 ],[-lz -L${exec_prefix}/lib])
 464
 465 # check for JPEG availability
 466 if test $with_jpeg = "yes" ; then {
 467         AC_CHECK_LIB(jpeg, jpeg_CreateCompress,[
 468                 JPEG_LIBS="-ljpeg"
 469                 AC_DEFINE(HAVE_LIBJPEG,[], [ Define if JPEG library is available ] )
 470                 AC_SUBST(JPEG_LIBS)
 471                 TARGET_JPEG="yes"
 472                 AM_CONDITIONAL(HAVE_LIBJPEG,true)
 473         ],[
 474                 AC_MSG_RESULT([ *** JPEG Output target disabled])
 475                 TARGET_JPEG="no"
 476                 AM_CONDITIONAL(HAVE_LIBJPEG,false)
 477         ],[
 478                 -L${exec_prefix}/lib
 479         ])
 480 } else {
 481         AC_MSG_RESULT([ *** JPEG Output target disabled])
 482         TARGET_JPEG="no"
 483         AM_CONDITIONAL(HAVE_LIBJPEG,false)
 484 } ; fi
 485
 486
 487
 488 MODULE_DIR='${libdir}/synfig/modules'
 489 moduledir=$libdir/synfig/modules
 490 AC_SUBST(MODULE_DIR)
 491 SYNFIGLIB_DIR=$libdir/synfig
 492 AC_SUBST(SYNFIGLIB_DIR)
 493
 494 # Check for unordered_map or hash_map headers
 495 AC_MSG_CHECKING([for unordered_map<int,int>::const_iterator])
 496 AC_COMPILE_IFELSE([
 497         AC_LANG_PROGRAM([
 498                 [#include <tr1/unordered_map>]
 499         ],[
 500                 [std::tr1::unordered_map<int,int>::const_iterator iter;]
 501         ])],[
 502         AC_MSG_RESULT([yes])
 503         AC_DEFINE([HASH_MAP_CLASS],[HASH_MAP_NAMESPACE::unordered_map],[The template name for unordered maps.])
 504         AC_DEFINE([HASH_MAP_H],[<tr1/unordered_map>],[The header file to include for unordered maps.])
 505         AC_DEFINE([HASH_MAP_NAMESPACE],[std::tr1],[The namespace for unordered maps.])
 506         AC_DEFINE([FUNCTIONAL_H],[<tr1/functional>],[The header file for hash<T>.])
 507         AC_DEFINE([FUNCTIONAL_HASH_ON_STRING],[1],[Define to 1 if hash<T> needs to use T=String rather than T=char* to hash strings.])
 508 ],[
 509         AC_MSG_RESULT([no])
 510         AC_CHECK_HEADERS([ext/hash_map],[
 511                 AC_DEFINE([HASH_MAP_CLASS],[HASH_MAP_NAMESPACE::hash_map],[The template name for unordered maps.])
 512                 AC_DEFINE([HASH_MAP_H],[<ext/hash_map>],[The header file to include for unordered maps.])
 513                 AC_DEFINE([HASH_MAP_NAMESPACE],[__gnu_cxx],[The namespace for unordered maps.])
 514                 AC_DEFINE([FUNCTIONAL_H],[<ext/functional>],[The header file for hash<T>.])
 515         ],[
 516                 AC_MSG_ERROR([C++ compiler does not seem to support unordered containers])
 517         ])
 518 ])
 519
 520 # Check for unordered_set or hash_set headers
 521 AC_MSG_CHECKING([for unordered_set<int,int>::const_iterator])
 522 AC_COMPILE_IFELSE([
 523         AC_LANG_PROGRAM([
 524                 [#include <tr1/unordered_set>]
 525         ],[
 526                 [std::tr1::unordered_set<int,int>::const_iterator iter;]
 527         ])],[
 528         AC_MSG_RESULT([yes])
 529         AC_DEFINE([HASH_SET_CLASS],[HASH_SET_NAMESPACE::unordered_set],[The template name for unordered sets.])
 530         AC_DEFINE([HASH_SET_H],[<tr1/unordered_set>],[The header file to include for unordered sets.])
 531         AC_DEFINE([HASH_SET_NAMESPACE],[std::tr1],[The namespace for unordered sets.])
 532 ],[
 533         AC_MSG_RESULT([no])
 534         AC_CHECK_HEADERS([ext/hash_set],[
 535                 AC_DEFINE([HASH_SET_CLASS],[HASH_SET_NAMESPACE::hash_set],[The template name for unordered sets.])
 536                 AC_DEFINE([HASH_SET_H],[<ext/hash_set>],[The header file to include for unordered sets.])
 537                 AC_DEFINE([HASH_SET_NAMESPACE],[__gnu_cxx],[The namespace for unordered sets.])
 538         ],[
 539                 AC_MSG_ERROR([C++ compiler does not seem to support unordered containers])
 540         ])
 541 ])
 542
 543
 544
 545
 546
 547 AC_CHECK_HEADERS(signal.h termios.h sys/errno.h)
 548
 549
 550 case "$host" in
 551         *mingw* | *cygwin*)
 552                 AM_CONDITIONAL(WIN32_PKG, true)
 553                 AM_CONDITIONAL(MACOSX_PKG, false)
 554         ;;
 555         *darwin*)
 556                 AM_CONDITIONAL(WIN32_PKG, false)
 557                 AM_CONDITIONAL(MACOSX_PKG, true)
 558         ;;
 559         *)
 560                 AM_CONDITIONAL(WIN32_PKG, false)
 561                 AM_CONDITIONAL(MACOSX_PKG, false)
 562         ;;
 563 esac
 564
 565
 566
 567 # -- H E A D E R S --------------------------------------------
 568
 569 AC_HEADER_SYS_WAIT
 570 AC_CHECK_HEADERS([process.h io.h fcntl.h])
 571
 572 # -- T Y P E S & S T R U C T S --------------------------------
 573
 574 # -- F U N C T I O N S ----------------------------------------
 575
 576 dnl AC_CHECK_FUNCS([floor pow sqrt],[],[
 577 dnl     AC_MSG_ERROR([ ** Could not find proper math functions.])
 578 dnl ])
 579
 580 AC_CHECK_FUNCS([fork])
 581 AC_CHECK_FUNCS([kill])
 582 AC_CHECK_FUNCS([pipe])
 583 AC_CHECK_FUNCS([waitpid])
 584
 585 AC_CHECK_FUNCS(
 586         [isnan],
 587         [],
 588         [
 589                 AC_CHECK_FUNCS(
 590                         [_isnan]
 591                 )
 592         ]
 593 )
 594
 595 AC_CHECK_FUNCS(
 596         [isnanf],
 597         [],
 598         [
 599                 AC_CHECK_FUNCS(
 600                         [_isnanf]
 601                 )
 602         ]
 603 )
 604
 605 AC_CHECK_FUNCS(
 606         [floorl],
 607         [],
 608         [
 609                 AC_CHECK_FUNCS(
 610                         [_floorl]
 611                 )
 612         ]
 613 )
 614
 615 AC_CHECK_LIB([pthread],[pthread_create])
 616
 617 # -- O U T P U T ----------------------------------------------
 618
 619 AC_SUBST(CFLAGS)
 620 AC_SUBST(CXXFLAGS)
 621 AC_SUBST(CPPFLAGS)
 622 AC_SUBST(LDFLAGS)
 623
 624 # this line is required for libtool 1.5.26 but must not be present for libtool 2.2.4...
 625 AC_CONFIG_SUBDIRS(libltdl)
 626
 627 CONFIG_LIBS="-lsynfig"
 628 CONFIG_CFLAGS="$CONFIG_CFLAGS"
 629 AC_SUBST(CONFIG_LIBS)
 630 AC_SUBST(CONFIG_CFLAGS)
 631 AC_SUBST(CONFIG_DEPS)
 632 AC_SUBST(ETL_CFLAGS)
 633
 634 SYNFIG_LIBS="$VIMAGE_LIBS $LIBXMLPP_LIBS $ETL_LIBS $LIBSIGC_LIBS $LTLIBINTL"
 635 SYNFIG_CFLAGS="$LIBXMLPP_CFLAGS $ETL_CFLAGS $LIBSIGC_CFLAGS $CONFIG_CFLAGS -DSYNFIG_NO_DEPRECATED -DLOCALEDIR=\\\"$localedir\\\""
 636
 637 CONFIG_CFLAGS="`echo $CONFIG_CFLAGS | sed s/-mno-cygwin//g | sed s/-mwindows//g`"
 638 SYNFIG_CFLAGS="`echo $SYNFIG_CFLAGS | sed s/-mno-cygwin//g | sed s/-mwindows//g`"
 639 SYNFIG_LIBS="`echo $SYNFIG_LIBS | sed s/-mno-cygwin//g | sed s/-mwindows//g`"
 640
 641 AC_SUBST(LIBADD_DL)
 642
 643 AC_SUBST(SYNFIG_LIBS)
 644 AC_SUBST(SYNFIG_CFLAGS)
 645 AC_SUBST(OPENEXR_HALF_LIBS)
 646
 647 AC_SUBST(API_VERSION)
 648
 649 synfigincludedir=$includedir/synfig-$API_VERSION
 650 AC_SUBST(synfigincludedir)
 651
 652 AC_CONFIG_FILES([synfig-config
 653 synfig.pc
 654 doxygen.cfg
 655 Makefile
 656 po/Makefile.in
 657 src/Makefile
 658 src/synfig/Makefile
 659 src/modules/Makefile
 660 src/modules/lyr_freetype/Makefile
 661 src/modules/lyr_std/Makefile
 662 src/modules/mod_bmp/Makefile
 663 src/modules/mod_dv/Makefile
 664 src/modules/mod_ffmpeg/Makefile
 665 src/modules/mod_filter/Makefile
 666 src/modules/mod_geometry/Makefile
 667 src/modules/mod_gif/Makefile
 668 src/modules/mod_gradient/Makefile
 669 src/modules/mod_imagemagick/Makefile
 670 src/modules/mod_jpeg/Makefile
 671 src/modules/mod_libavcodec/Makefile
 672 src/modules/mod_magickpp/Makefile
 673 src/modules/mod_mng/Makefile
 674 src/modules/mod_noise/Makefile
 675 src/modules/mod_openexr/Makefile
 676 src/modules/mod_particle/Makefile
 677 src/modules/mod_png/Makefile
 678 src/modules/mod_ppm/Makefile
 679 src/modules/mod_yuv420p/Makefile
 680 src/modules/example/Makefile
 681 src/tool/Makefile
 682 src/modules/synfig_modules.cfg
 683 examples/walk/Makefile
 684 examples/Makefile
 685 win32inst.nsi
 686 pkg-info/macosx/synfig-core.info
 687 ])
 688 ## src/modules/trgt_mpg/Makefile
 689 ## src/modules/mptr_mplayer/Makefile
 690 AC_OUTPUT
 691
 692 # -- S U M M A R Y --------------------------------------------
 693
 694 echo "
 695 $PACKAGE_NAME v.$VERSION
 696 Configuration Summary
 697 - - - - - -
 698
 699 Install Prefix -------------------> $prefix
 700 Module directory -----------------> $moduledir
 701 Build Platform -------------------> $build
 702 Host Platform --------------------> $host
 703 Arc Profiling --------------------> $profile_arcs
 704 GProf Profiling ------------------> $profiling
 705 Debug Mode -----------------------> $debug ($debug_flags)
 706 Optimization ---------------------> $optimization
 707 PNG output target support --------> $TARGET_PNG
 708 MNG output target support --------> $TARGET_MNG
 709 JPEG output target support -------> $TARGET_JPEG
 710 ETL_CFLAGS -----------------------> $ETL_CFLAGS
 711 FreeType2 ------------------------> $with_freetype
 712 fontconfig -----------------------> $with_fontconfig
 713 libavcodec -----------------------> $with_libavcodec
 714 libswscale -----------------------> $with_libswscale
 715 vImage ---------------------------> $with_vimage
 716 ImageMagick ----------------------> $with_imagemagick
 717 Magick++ -------------------------> $with_magickpp
 718 FFMPEG ---------------------------> $with_ffmpeg
 719 libdv ----------------------------> $with_libdv
 720 OpenEXR --------------------------> $with_openexr
 721 Using OpenEXR's \"half\" type ------> $use_openexr_half
 722
 723 "'$'"CXX -----------------------------> '$CXX'
 724 "'$'"CXXFLAGS ------------------------> '$CXXFLAGS'
 725 "'$'"SYNFIG_LIBS ---------------------> '$SYNFIG_LIBS'
 726 "'$'"LIBXMLPP_LIBS -------------------> '$LIBXMLPP_LIBS'
 727 "'$'"ETL_LIBS ------------------------> '$ETL_LIBS'
 728 "'$'"LIBSIGC_LIBS --------------------> '$LIBSIGC_LIBS'
 729 "'$'"SYNFIG_CFLAGS -------------------> '$SYNFIG_CFLAGS'
 730 "'$'"LIBADD_DL -----------------------> '$LIBADD_DL'
 731 "