synfig-core/trunk/configure.ac

   1 # $Id$
   2
   3 # -- I N I T --------------------------------------------------
   4
   5 AC_INIT([Synfig Core],[0.61.08],[http://synfig.org/Bugs],[synfig])
   6 AC_REVISION
   7
   8 AC_CONFIG_AUX_DIR(config)
   9 AC_CONFIG_HEADERS([config.h])
  10 AC_CANONICAL_HOST
  11 dnl AC_CANONICAL_TARGET
  12
  13 AM_INIT_AUTOMAKE([nostdinc])
  14 AM_MAINTAINER_MODE
  15
  16 AC_LIBLTDL_CONVENIENCE
  17 AC_SUBST(INCLTDL)
  18 AC_SUBST(LIBLTDL)
  19
  20 API_VERSION=0.0
  21
  22
  23 AC_DEFINE(LT_SCOPE,[extern],[LibLTDL is linked staticly])
  24
  25
  26
  27
  28 # -- V A R I A B L E S ----------------------------------------
  29
  30 SVN_REPOSITORY=http://svn.voria.com/code/synfig-core
  31 AC_SUBST(SVN_REPOSITORY)
  32
  33 # -- P R O G R A M S ------------------------------------------
  34
  35 AC_PROG_CC
  36 AC_GNU_SOURCE
  37 AC_PROG_CXX
  38 AC_PROG_CPP
  39 AC_PROG_CXXCPP
  40 AC_PROG_INSTALL
  41
  42 AC_LANG([C++])
  43
  44
  45 # -- A R G U M E N T S ----------------------------------------
  46
  47
  48 AC_ARG_DEBUG
  49 AC_ARG_OPTIMIZATION
  50 AC_ARG_WARNINGS
  51 AC_ARG_PROFILING
  52 AC_ARG_PROFILE_ARCS
  53 AC_ARG_BRANCH_PROBABILITIES
  54
  55 AC_ARG_ENABLE(g5opt,[
  56   --enable-g5opt           enable optimizations specific to G5 proc],[
  57 #       CXXFLAGS="$CXXFLAGS -fastf -fPIC"
  58 #       CFLAGS="$CFLAGS -fastf -fPIC"
  59         CXXFLAGS="$CXXFLAGS -mtune=G5 -falign-loops=32"
  60         CFLAGS="$CFLAGS -mtune=G5"
  61 ],
  62 [
  63         true
  64 ])
  65
  66 #MINGW_FLAGS="-mno-cygwin"
  67
  68 AC_WIN32_QUIRKS
  69
  70 # If we are in debug mode, use the debugging version of the
  71 # Microsoft Visual C Runtime Library
  72 #if [[ $debug = "yes" ]] ; then {
  73 #       WIN32_DEBUG_LIBRARY="msvcr70d"
  74 #       WIN32_DEBUG_LIBRARY="msvcrtd"
  75 #       LIBTOOL_PATCH_SED="$LIBTOOL_PATCH_SED
  76 #               s/-lmsvcrt/-l$WIN32_DEBUG_LIBRARY/g;
  77 #       ";
  78 #} ; fi
  79
  80 AC_LIBTOOL_WIN32_DLL
  81 AC_LIBTOOL_DLOPEN
  82 AC_DISABLE_STATIC
  83 AC_ENABLE_SHARED
  84 AC_PROG_LIBTOOL
  85 AC_SUBST(LIBTOOL_DEPS)
  86 AC_LIBTOOL_PATCH
  87
  88 #if [[ "$LIBTOOL_PATCH_SED""x" != "x" ]] ; then {
  89 #       printf "Patching libtool... "
  90 #       cat libtool | sed "$LIBTOOL_PATCH_SED" > libtool2
  91 #       rm libtool
  92 #       mv libtool2 libtool
  93 #       chmod +x libtool
  94 #       AC_MSG_RESULT([patched])
  95 #} fi ;
  96
  97
  98 dnl
  99 dnl dynamic linker
 100 dnl
 101 AC_CHECK_LIB(c, dlopen,
 102         DYNAMIC_LD_LIBS="",
 103         AC_CHECK_LIB(
 104                 dl,
 105                 dlopen,
 106         DYNAMIC_LD_LIBS="-ldl",
 107             DYNAMIC_LD_LIBS=""
 108         )
 109 )
 110
 111 AC_SUBST(DYNAMIC_LD_LIBS)
 112
 113 AC_ARG_ENABLE(half,[
 114   --enable-half           Use OpenEXR's "half" type for color],[
 115         use_openexr_half=$enableval
 116 ],
 117 [
 118         use_openexr_half="no"
 119 ])
 120
 121
 122
 123 AC_ARG_ENABLE(layer-profiling,[
 124   --enable-layer-profiling       Enable layer profiling],[
 125         use_layerprofiling=$enableval
 126 ],
 127 [
 128         use_layerprofiling="no"
 129 ])
 130 if test $use_layerprofiling = "yes" ; then {
 131         AC_DEFINE(SYNFIG_PROFILE_LAYERS,[1],[enable layer profiling])
 132 } ; fi
 133
 134
 135
 136
 137 AC_ARG_WITH(imagemagick,[
 138   --without-imagemagick   Disable support for ImageMagick],[
 139 ],[
 140     AC_CHECK_PROG([imagemagick_convert],[convert],[yes],[no])
 141     with_imagemagick=$imagemagick_convert
 142 ])
 143 if test $with_imagemagick = "no" ; then {
 144         AM_CONDITIONAL(WITH_IMAGEMAGICK,false)
 145 } else {
 146         AM_CONDITIONAL(WITH_IMAGEMAGICK,true)
 147 } ; fi
 148
 149
 150
 151
 152
 153 AC_ARG_WITH(magickpp,[
 154   --without-magickpp        Disable support for Magick++],[
 155 ],[
 156         with_magickpp="yes"
 157 ])
 158 if test $with_magickpp = "yes" ; then {
 159   AC_CHECK_HEADER([Magick++.h],[
 160         MAGICKPP_LIBS="-lMagick++"
 161         AC_DEFINE(HAVE_MAGICKPP,[], [ Define if Magick++ library is available ] )
 162         AC_SUBST(MAGICKPP_LIBS)
 163         AM_CONDITIONAL(HAVE_LIBMAGICKPP,true)
 164         AC_CHECK_LIB(Magick,OptimizeImageTransparency,[
 165                 AC_DEFINE(HAVE_MAGICK_OPTIMIZE,[], [ Define if Magick++ defines OptimizeImageTransparency() ] )
 166                 AM_CONDITIONAL(HAVE_MAGICK_OPTIMIZE,true)
 167         ],[
 168                 AC_MSG_RESULT([ *** OptimizeImageTransparency() not available - need ImageMagick 6.3 or newer ])
 169                 AM_CONDITIONAL(HAVE_MAGICK_OPTIMIZE,false)
 170         ])
 171   ],[
 172         with_magickpp="no"
 173         AC_MSG_RESULT([ *** Magick++ Output target disabled])
 174         TARGET_MAGICKPP="no"
 175         AM_CONDITIONAL(HAVE_LIBMAGICKPP,false)
 176         AM_CONDITIONAL(HAVE_MAGICK_OPTIMIZE,false)
 177   ])
 178 } else {
 179         AM_CONDITIONAL(HAVE_LIBMAGICKPP,false)
 180         AM_CONDITIONAL(HAVE_MAGICK_OPTIMIZE,false)
 181 } ; fi
 182
 183
 184
 185
 186 AC_ARG_WITH(ffmpeg,[
 187   --without-ffmpeg        Disable support for FFMPEG],[
 188 ],[
 189         with_ffmpeg="yes"
 190 ])
 191 if test $with_ffmpeg = "no" ; then {
 192         AM_CONDITIONAL(WITH_FFMPEG,false)
 193 } else {
 194         AM_CONDITIONAL(WITH_FFMPEG,true)
 195 } ; fi
 196
 197
 198
 199
 200 AC_ARG_WITH(vimage,[
 201   --with-vimage        Enable support for apple vImage],[
 202 ],[
 203         with_vimage="no"
 204 ])
 205 if test $with_vimage = "no" ; then {
 206         AM_CONDITIONAL(WITH_VIMAGE,false)
 207 } else {
 208         AM_CONDITIONAL(WITH_VIMAGE,true)
 209         AC_DEFINE(HAS_VIMAGE,[1],[enable apple vImage])
 210         VIMAGE_LIBS="-Wc,-framework -Wc,Accelerate"
 211
 212 } ; fi
 213
 214
 215
 216 AC_ARG_WITH(libdv,[
 217   --without-libdv         Disable support for libdv],[
 218 ],[
 219         with_libdv="yes"
 220 ])
 221 if test $with_libdv = "no" ; then {
 222         AM_CONDITIONAL(WITH_LIBDV,false)
 223 } else {
 224         AM_CONDITIONAL(WITH_LIBDV,true)
 225 } ; fi
 226
 227
 228
 229
 230 # LIBAVCODEC CHECK--------------------
 231
 232 AC_ARG_WITH(libavcodec,[
 233   --without-libavcodec         disable support for libavcodec (Default=auto)],[
 234 ],[
 235         with_libavcodec="yes"
 236 ])
 237
 238 if test $with_libavcodec != "no" ; then {
 239         PKG_CHECK_MODULES(LIBAVCODEC, [libavcodec libavformat],[],[echo no; with_libavcodec="no"])
 240 } ; fi
 241 if test $with_libavcodec = "yes" ; then {
 242         AC_DEFINE(WITH_LIBAVCODEC,[],[enable libavcodec support])
 243         AM_CONDITIONAL(WITH_LIBAVCODEC,true)
 244 } else {
 245         AM_CONDITIONAL(WITH_LIBAVCODEC,false)
 246 } ; fi
 247
 248
 249 if test $with_libavcodec = "yes" ; then {
 250         AC_ARG_WITH(libswscale,
 251                 [AS_HELP_STRING([--without-libswscale],
 252                         [disable support for libswscale (Default=auto)])],
 253                 [],
 254                 [with_libswscale="yes"]
 255         )
 256
 257         if test $with_libswscale != "no" ; then {
 258                 PKG_CHECK_MODULES(LIBSWSCALE, [libswscale], [], [echo no; with_libswscale="no"])
 259         } ; fi
 260
 261         if test $with_libswscale = "yes" ; then {
 262                 AC_DEFINE(WITH_LIBSWSCALE, [], [enable libswscale support])
 263         } else {
 264                 AC_CHECK_LIB(avcodec, img_convert,
 265                         [AC_MSG_RESULT([ *** Using deprecated function img_convert.])],
 266                         [AC_MSG_FAILURE([Neither libswscale nor function img_convert was found.])],
 267                         []
 268                 )
 269         } ; fi
 270 } ; fi
 271 AM_CONDITIONAL(WITH_LIBSWSCALE, test "x$with_libswscale" = "xyes")
 272
 273
 274 # FREETYPE2 CHECK--------------------
 275
 276 AC_ARG_WITH(freetype,[
 277   --without-freetype         disable support for freetype (Default=auto)],[
 278 ],[
 279         with_freetype="yes"
 280 ])
 281
 282 if test $with_freetype != "no" ; then {
 283         PKG_CHECK_MODULES(FREETYPE, freetype2,[
 284                 with_freetype="yes"
 285         ],[
 286                 PKG_CHECK_MODULES(FREETYPE, xft,[
 287                         with_freetype="yes"
 288                 ],[
 289                         with_freetype="no"
 290                 ])
 291         ])
 292 } ; fi
 293
 294 if test $with_freetype = "no" ; then {
 295         AM_CONDITIONAL(WITH_FREETYPE,false)
 296 } else {
 297         AM_CONDITIONAL(WITH_FREETYPE,true)
 298 } ; fi
 299
 300
 301 # FONTCONFIG CHECK--------------------
 302
 303 AC_ARG_WITH(fontconfig,[
 304   --without-fontconfig         disable support for fontconfig (Default=auto)],[
 305 ],[
 306         with_fontconfig="yes"
 307 ])
 308
 309 if test $with_fontconfig != "no" ; then {
 310         PKG_CHECK_MODULES(FONTCONFIG, fontconfig,[
 311                 with_fontconfig="yes"
 312         ],[
 313                 with_fontconfig="no"
 314         ])
 315 } ; fi
 316
 317 if test $with_fontconfig = "yes" ; then {
 318         AC_DEFINE(WITH_FONTCONFIG,[],[enable fontconfig support])
 319         AM_CONDITIONAL(WITH_FONTCONFIG,true)
 320 } else {
 321         AM_CONDITIONAL(WITH_FONTCONFIG,false)
 322 } ; fi
 323
 324
 325 # OPENEXR CHECK------------------------
 326 AC_ARG_WITH(openexr,[
 327   --without-openexr        Disable support for ILM's OpenEXR],[
 328 ],[
 329         with_openexr="yes"
 330 ])
 331 if test $with_openexr = "yes" ; then {
 332         PKG_CHECK_MODULES(OPENEXR, OpenEXR,[
 333                 AC_DEFINE(HAVE_OPENEXR,[], [ Define if OpenEXR is available ] )
 334                 AM_CONDITIONAL(WITH_OPENEXR,true)
 335         ],
 336         [
 337                 with_openexr="no"
 338         ])
 339 } ; fi
 340 if test $with_openexr = "no" ; then {
 341         AM_CONDITIONAL(WITH_OPENEXR,false)
 342         use_openexr_half="no"
 343 } ; fi
 344 if test $use_openexr_half = yes ; then {
 345         AC_MSG_RESULT([ ** Using OpenEXR Half.])
 346         CONFIG_DEPS="$CONFIG_DEPS OpenEXR"
 347         CONFIG_CFLAGS="$CONFIG_CFLAGS -DUSE_HALF_TYPE"
 348         OPENEXR_HALF_LIBS="-lHalf"
 349 } else {
 350         OPENEXR_HALF_LIBS=""
 351 } ; fi
 352
 353
 354
 355
 356
 357 # -- L I B R A R I E S ----------------------------------------
 358
 359 AC_LIB_LTDL
 360
 361 ALL_LINGUAS="es fr"
 362 AM_GNU_GETTEXT([external])
 363 # This is here so autoreconf will run autopoint
 364 AM_GNU_GETTEXT_VERSION([0.14.4])
 365 localedir="$datadir/locale"
 366
 367 PKG_CHECK_MODULES(ETL, [ETL >= 0.04.11],,[
 368         AC_MSG_ERROR([ ** You need to install the ETL (version 0.04.11 or greater).])
 369 ])
 370 CONFIG_DEPS="$CONFIG_DEPS ETL"
 371
 372
 373 PKG_CHECK_MODULES(LIBXMLPP, libxml++-2.6,[
 374         CONFIG_DEPS="$CONFIG_DEPS libxml++-2.6"
 375 ],[
 376         PKG_CHECK_MODULES(LIBXMLPP, libxml++-1.0,[
 377                 CONFIG_DEPS="$CONFIG_DEPS libxml++-1.0"
 378         ],[
 379                 AC_MSG_ERROR([ ** You need to install libxml++, either verison 2.6 or 1.0.])
 380         ])
 381 ])
 382
 383 PKG_CHECK_MODULES(LIBSIGC, [sigc++-2.0],,[
 384         AC_MSG_ERROR([ ** libsigc++-2.0 not found. It is required. You should really install it.])
 385 dnl     PKG_CHECK_MODULES(LIBSIGC, [sigc++-1.2],,[
 386 dnl             AC_MSG_ERROR([ ** At least libsigc++-1.2 is required.])
 387 dnl     ])
 388 ])
 389 CONFIG_DEPS="$CONFIG_DEPS sigc++-2.0"
 390
 391 dnl PKG_CHECK_MODULES(GLIB, glib-2.0,[GLIB="yes"],[GLIB="no"])
 392
 393
 394
 395
 396
 397 TARGET_PNG="yes"
 398 TARGET_MNG="yes"
 399 TARGET_JPEG="yes"
 400
 401 AC_CHECK_LIB(png, png_write_row,[
 402         PNG_LIBS="-lpng"
 403         AC_DEFINE(HAVE_LIBPNG,[], [ Define if PNG library is available ] )
 404         AC_SUBST(PNG_LIBS)
 405         AM_CONDITIONAL(HAVE_LIBPNG,true)
 406 ],[
 407         AC_CHECK_LIB(png12, png_write_row,[
 408         PNG_LIBS="-lpng12"
 409         AC_DEFINE(HAVE_LIBPNG,[])
 410         AC_SUBST(PNG_LIBS)
 411         AM_CONDITIONAL(HAVE_LIBPNG,true)
 412         ],[
 413                 AC_MSG_RESULT([ *** PNG Output target disabled])
 414                 TARGET_PNG="no"
 415                 AM_CONDITIONAL(HAVE_LIBPNG,false)
 416         ],[-lz -L${exec_prefix}/lib])
 417 ],[-lz -L${exec_prefix}/lib])
 418
 419 AC_CHECK_LIB(mng, mng_initialize,[
 420         MNG_LIBS="-lmng -lz"
 421         AC_DEFINE(HAVE_LIBMNG,[], [ Define if MNG library is available ] )
 422         AC_SUBST(MNG_LIBS)
 423         AM_CONDITIONAL(HAVE_LIBMNG,true)
 424 ],[
 425         AC_MSG_RESULT([ *** MNG Output target disabled])
 426         TARGET_MNG="no"
 427         AM_CONDITIONAL(HAVE_LIBMNG,false)
 428 ],[-lz -L${exec_prefix}/lib])
 429
 430 AC_CHECK_LIB(jpeg, jpeg_CreateCompress,[
 431         JPEG_LIBS="-ljpeg"
 432         AC_DEFINE(HAVE_LIBJPEG,[], [ Define if JPEG library is available ] )
 433         AC_SUBST(JPEG_LIBS)
 434         AM_CONDITIONAL(HAVE_LIBJPEG,true)
 435 ],[
 436         AC_MSG_RESULT([ *** JPEG Output target disabled])
 437         TARGET_JPEG="no"
 438         AM_CONDITIONAL(HAVE_LIBJPEG,false)
 439 ],[-L${exec_prefix}/lib])
 440
 441
 442 dnl AC_CHECK_HEADERS(jpeglib.h,[],[
 443 dnl     AC_MSG_RESULT([ *** JPEG Output target disabled])
 444 dnl     TARGET_JPEG="no"
 445 dnl     AM_CONDITIONAL(HAVE_LIBJPEG,false)
 446 dnl ])
 447
 448
 449
 450 MODULE_DIR='${libdir}/synfig/modules'
 451 moduledir=$libdir/synfig/modules
 452 AC_SUBST(MODULE_DIR)
 453 SYNFIGLIB_DIR=$libdir/synfig
 454 AC_SUBST(SYNFIGLIB_DIR)
 455
 456 # Check for unordered_map or hash_map headers
 457 AC_MSG_CHECKING([for unordered_map<int,int>::const_iterator])
 458 AC_COMPILE_IFELSE([
 459         AC_LANG_PROGRAM([
 460                 [#include <tr1/unordered_map>]
 461         ],[
 462                 [std::tr1::unordered_map<int,int>::const_iterator iter;]
 463         ])],[
 464         AC_MSG_RESULT([yes])
 465         AC_DEFINE([HASH_MAP_CLASS],[HASH_MAP_NAMESPACE::unordered_map],[The template name for unordered maps.])
 466         AC_DEFINE([HASH_MAP_H],[<tr1/unordered_map>],[The header file to include for unordered maps.])
 467         AC_DEFINE([HASH_MAP_NAMESPACE],[std::tr1],[The namespace for unordered maps.])
 468         AC_DEFINE([FUNCTIONAL_H],[<tr1/functional>],[The header file for hash<T>.])
 469         AC_DEFINE([FUNCTIONAL_HASH_ON_STRING],[1],[Define to 1 if hash<T> needs to use T=String rather than T=char* to hash strings.])
 470 ],[
 471         AC_MSG_RESULT([no])
 472         AC_CHECK_HEADERS([ext/hash_map],[
 473                 AC_DEFINE([HASH_MAP_CLASS],[HASH_MAP_NAMESPACE::hash_map],[The template name for unordered maps.])
 474                 AC_DEFINE([HASH_MAP_H],[<ext/hash_map>],[The header file to include for unordered maps.])
 475                 AC_DEFINE([HASH_MAP_NAMESPACE],[__gnu_cxx],[The namespace for unordered maps.])
 476                 AC_DEFINE([FUNCTIONAL_H],[<ext/functional>],[The header file for hash<T>.])
 477         ],[
 478                 AC_MSG_ERROR([C++ compiler does not seem to support unordered containers])
 479         ])
 480 ])
 481
 482 # Check for unordered_set or hash_set headers
 483 AC_MSG_CHECKING([for unordered_set<int,int>::const_iterator])
 484 AC_COMPILE_IFELSE([
 485         AC_LANG_PROGRAM([
 486                 [#include <tr1/unordered_set>]
 487         ],[
 488                 [std::tr1::unordered_set<int,int>::const_iterator iter;]
 489         ])],[
 490         AC_MSG_RESULT([yes])
 491         AC_DEFINE([HASH_SET_CLASS],[HASH_SET_NAMESPACE::unordered_set],[The template name for unordered sets.])
 492         AC_DEFINE([HASH_SET_H],[<tr1/unordered_set>],[The header file to include for unordered sets.])
 493         AC_DEFINE([HASH_SET_NAMESPACE],[std::tr1],[The namespace for unordered sets.])
 494 ],[
 495         AC_MSG_RESULT([no])
 496         AC_CHECK_HEADERS([ext/hash_set],[
 497                 AC_DEFINE([HASH_SET_CLASS],[HASH_SET_NAMESPACE::hash_set],[The template name for unordered sets.])
 498                 AC_DEFINE([HASH_SET_H],[<ext/hash_set>],[The header file to include for unordered sets.])
 499                 AC_DEFINE([HASH_SET_NAMESPACE],[__gnu_cxx],[The namespace for unordered sets.])
 500         ],[
 501                 AC_MSG_ERROR([C++ compiler does not seem to support unordered containers])
 502         ])
 503 ])
 504
 505
 506
 507
 508
 509 AC_CHECK_HEADERS(signal.h termios.h sys/errno.h)
 510
 511
 512 case "$host" in
 513         *mingw* | *cygwin*)
 514                 AM_CONDITIONAL(WIN32_PKG, true)
 515                 AM_CONDITIONAL(MACOSX_PKG, false)
 516         ;;
 517         *darwin*)
 518                 AM_CONDITIONAL(WIN32_PKG, false)
 519                 AM_CONDITIONAL(MACOSX_PKG, true)
 520         ;;
 521         *)
 522                 AM_CONDITIONAL(WIN32_PKG, false)
 523                 AM_CONDITIONAL(MACOSX_PKG, false)
 524         ;;
 525 esac
 526
 527
 528
 529 # -- H E A D E R S --------------------------------------------
 530
 531 AC_HEADER_SYS_WAIT
 532 AC_CHECK_HEADERS([process.h io.h fcntl.h])
 533
 534 # -- T Y P E S & S T R U C T S --------------------------------
 535
 536 # -- F U N C T I O N S ----------------------------------------
 537
 538 dnl AC_CHECK_FUNCS([floor pow sqrt],[],[
 539 dnl     AC_MSG_ERROR([ ** Could not find proper math functions.])
 540 dnl ])
 541
 542 AC_CHECK_FUNCS([fork])
 543 AC_CHECK_FUNCS([kill])
 544 AC_CHECK_FUNCS([pipe])
 545 AC_CHECK_FUNCS([waitpid])
 546
 547 AC_CHECK_FUNCS(
 548         [isnan],
 549         [],
 550         [
 551                 AC_CHECK_FUNCS(
 552                         [_isnan]
 553                 )
 554         ]
 555 )
 556
 557 AC_CHECK_FUNCS(
 558         [isnanf],
 559         [],
 560         [
 561                 AC_CHECK_FUNCS(
 562                         [_isnanf]
 563                 )
 564         ]
 565 )
 566
 567 AC_CHECK_FUNCS(
 568         [floorl],
 569         [],
 570         [
 571                 AC_CHECK_FUNCS(
 572                         [_floorl]
 573                 )
 574         ]
 575 )
 576
 577 AC_CHECK_LIB([pthread],[pthread_create])
 578
 579 # -- O U T P U T ----------------------------------------------
 580
 581 AC_SUBST(CFLAGS)
 582 AC_SUBST(CXXFLAGS)
 583 AC_SUBST(CPPFLAGS)
 584 AC_SUBST(LDFLAGS)
 585
 586 AC_CONFIG_SUBDIRS(libltdl)
 587
 588 CONFIG_LIBS="-lsynfig"
 589 CONFIG_CFLAGS="$CONFIG_CFLAGS"
 590 AC_SUBST(CONFIG_LIBS)
 591 AC_SUBST(CONFIG_CFLAGS)
 592 AC_SUBST(CONFIG_DEPS)
 593 AC_SUBST(ETL_CFLAGS)
 594
 595 SYNFIG_LIBS="$VIMAGE_LIBS $LIBXMLPP_LIBS $ETL_LIBS $LIBSIGC_LIBS $LTLIBINTL"
 596 SYNFIG_CFLAGS="$LIBXMLPP_CFLAGS $ETL_CFLAGS $LIBSIGC_CFLAGS $CONFIG_CFLAGS -DSYNFIG_NO_DEPRECATED -DLOCALEDIR=\\\"$localedir\\\""
 597
 598 CONFIG_CFLAGS="`echo $CONFIG_CFLAGS | sed s/-mno-cygwin//g | sed s/-mwindows//g`"
 599 SYNFIG_CFLAGS="`echo $SYNFIG_CFLAGS | sed s/-mno-cygwin//g | sed s/-mwindows//g`"
 600 SYNFIG_LIBS="`echo $SYNFIG_LIBS | sed s/-mno-cygwin//g | sed s/-mwindows//g`"
 601
 602 AC_SUBST(LIBADD_DL)
 603
 604 AC_SUBST(SYNFIG_LIBS)
 605 AC_SUBST(SYNFIG_CFLAGS)
 606 AC_SUBST(OPENEXR_HALF_LIBS)
 607
 608 AC_SUBST(API_VERSION)
 609
 610 synfigincludedir=$includedir/synfig-$API_VERSION
 611 AC_SUBST(synfigincludedir)
 612
 613 AC_CONFIG_FILES([synfig-config
 614 synfig.pc
 615 doxygen.cfg
 616 Makefile
 617 po/Makefile.in
 618 src/Makefile
 619 src/synfig/Makefile
 620 src/modules/Makefile
 621 src/modules/lyr_freetype/Makefile
 622 src/modules/lyr_std/Makefile
 623 src/modules/mod_bmp/Makefile
 624 src/modules/mod_dv/Makefile
 625 src/modules/mod_ffmpeg/Makefile
 626 src/modules/mod_filter/Makefile
 627 src/modules/mod_geometry/Makefile
 628 src/modules/mod_gif/Makefile
 629 src/modules/mod_gradient/Makefile
 630 src/modules/mod_imagemagick/Makefile
 631 src/modules/mod_jpeg/Makefile
 632 src/modules/mod_libavcodec/Makefile
 633 src/modules/mod_magickpp/Makefile
 634 src/modules/mod_mng/Makefile
 635 src/modules/mod_noise/Makefile
 636 src/modules/mod_openexr/Makefile
 637 src/modules/mod_particle/Makefile
 638 src/modules/mod_png/Makefile
 639 src/modules/mod_ppm/Makefile
 640 src/modules/mod_yuv420p/Makefile
 641 src/tool/Makefile
 642 src/modules/synfig_modules.cfg
 643 examples/walk/Makefile
 644 examples/Makefile
 645 win32inst.nsi
 646 pkg-info/macosx/synfig-core.info
 647 ])
 648 ## src/modules/trgt_mpg/Makefile
 649 ## src/modules/mptr_mplayer/Makefile
 650 AC_OUTPUT
 651
 652 # -- S U M M A R Y --------------------------------------------
 653
 654 echo "
 655 $PACKAGE_NAME v.$VERSION
 656 Configuration Summary
 657 - - - - - -
 658
 659 Install Prefix -------------------> $prefix
 660 Module directory -----------------> $moduledir
 661 Build Platform -------------------> $build
 662 Host Platform --------------------> $host
 663 Arc Profiling --------------------> $profile_arcs
 664 GProf Profiling ------------------> $profiling
 665 Debug Mode -----------------------> $debug ($debug_flags)
 666 Optimization ---------------------> $optimization
 667 PNG output target support --------> $TARGET_PNG
 668 MNG output target support --------> $TARGET_MNG
 669 JPEG output target support -------> $TARGET_JPEG
 670 ETL_CFLAGS -----------------------> $ETL_CFLAGS
 671 FreeType2 ------------------------> $with_freetype
 672 fontconfig -----------------------> $with_fontconfig
 673 libavcodec -----------------------> $with_libavcodec
 674 libswscale -----------------------> $with_libswscale
 675 vImage ---------------------------> $with_vimage
 676 ImageMagick ----------------------> $with_imagemagick
 677 Magick++ -------------------------> $with_magickpp
 678 FFMPEG ---------------------------> $with_ffmpeg
 679 libdv ----------------------------> $with_libdv
 680 OpenEXR --------------------------> $with_openexr
 681 Using OpenEXR's \"half\" type ------> $use_openexr_half
 682
 683 "'$'"CXX -----------------------------> '$CXX'
 684 "'$'"CXXFLAGS ------------------------> '$CXXFLAGS'
 685 "'$'"SYNFIG_LIBS ---------------------> '$SYNFIG_LIBS'
 686 "'$'"LIBXMLPP_LIBS -------------------> '$LIBXMLPP_LIBS'
 687 "'$'"ETL_LIBS ------------------------> '$ETL_LIBS'
 688 "'$'"LIBSIGC_LIBS --------------------> '$LIBSIGC_LIBS'
 689 "'$'"SYNFIG_CFLAGS -------------------> '$SYNFIG_CFLAGS'
 690 "'$'"LIBADD_DL -----------------------> '$LIBADD_DL'
 691 "