synfig-core/trunk/configure.ac

   1 # $Id$
   2
   3 # -- I N I T --------------------------------------------------
   4
   5 AC_INIT([Synfig Core],[0.61.09],[http://synfig.org/Bugs],[synfig])
   6 AC_REVISION
   7
   8 AC_CONFIG_AUX_DIR(config)
   9 AC_CONFIG_HEADERS([config.h])
  10 AC_CANONICAL_HOST
  11 dnl AC_CANONICAL_TARGET
  12
  13 AM_INIT_AUTOMAKE([nostdinc])
  14 AM_MAINTAINER_MODE
  15
  16 AC_LIBLTDL_CONVENIENCE
  17 AC_SUBST(INCLTDL)
  18 AC_SUBST(LIBLTDL)
  19
  20 API_VERSION=0.0
  21
  22
  23 AC_DEFINE(LT_SCOPE,[extern],[LibLTDL is linked staticly])
  24
  25
  26
  27
  28 # -- V A R I A B L E S ----------------------------------------
  29
  30 SVN_REPOSITORY=https://synfig.svn.sourceforge.net/svnroot/synfig/synfig-core
  31 AC_SUBST(SVN_REPOSITORY)
  32
  33 # -- P R O G R A M S ------------------------------------------
  34
  35 AC_PROG_CC
  36 AC_GNU_SOURCE
  37 AC_PROG_CXX
  38 AC_PROG_CPP
  39 AC_PROG_CXXCPP
  40 AC_PROG_INSTALL
  41
  42 AC_LANG([C++])
  43
  44
  45 # -- A R G U M E N T S ----------------------------------------
  46
  47
  48 AC_ARG_DEBUG
  49 AC_ARG_OPTIMIZATION
  50 AC_ARG_WARNINGS
  51 AC_ARG_PROFILING
  52 AC_ARG_PROFILE_ARCS
  53 AC_ARG_BRANCH_PROBABILITIES
  54
  55 AC_ARG_ENABLE(g5opt,[
  56   --enable-g5opt           enable optimizations specific to G5 proc],[
  57 #       CXXFLAGS="$CXXFLAGS -fastf -fPIC"
  58 #       CFLAGS="$CFLAGS -fastf -fPIC"
  59         CXXFLAGS="$CXXFLAGS -mtune=G5 -falign-loops=32"
  60         CFLAGS="$CFLAGS -mtune=G5"
  61 ],
  62 [
  63         true
  64 ])
  65
  66 #MINGW_FLAGS="-mno-cygwin"
  67
  68 AC_WIN32_QUIRKS
  69
  70 # If we are in debug mode, use the debugging version of the
  71 # Microsoft Visual C Runtime Library
  72 #if [[ $debug = "yes" ]] ; then {
  73 #       WIN32_DEBUG_LIBRARY="msvcr70d"
  74 #       WIN32_DEBUG_LIBRARY="msvcrtd"
  75 #       LIBTOOL_PATCH_SED="$LIBTOOL_PATCH_SED
  76 #               s/-lmsvcrt/-l$WIN32_DEBUG_LIBRARY/g;
  77 #       ";
  78 #} ; fi
  79
  80 AC_LIBTOOL_WIN32_DLL
  81 AC_LIBTOOL_DLOPEN
  82 AC_DISABLE_STATIC
  83 AC_ENABLE_SHARED
  84 AC_PROG_LIBTOOL
  85 AC_SUBST(LIBTOOL_DEPS)
  86 AC_LIBTOOL_PATCH
  87
  88 #if [[ "$LIBTOOL_PATCH_SED""x" != "x" ]] ; then {
  89 #       printf "Patching libtool... "
  90 #       cat libtool | sed "$LIBTOOL_PATCH_SED" > libtool2
  91 #       rm libtool
  92 #       mv libtool2 libtool
  93 #       chmod +x libtool
  94 #       AC_MSG_RESULT([patched])
  95 #} fi ;
  96
  97
  98 dnl
  99 dnl dynamic linker
 100 dnl
 101 AC_CHECK_LIB(c, dlopen,
 102         DYNAMIC_LD_LIBS="",
 103         AC_CHECK_LIB(
 104                 dl,
 105                 dlopen,
 106         DYNAMIC_LD_LIBS="-ldl",
 107             DYNAMIC_LD_LIBS=""
 108         )
 109 )
 110
 111 AC_SUBST(DYNAMIC_LD_LIBS)
 112
 113 AC_ARG_ENABLE(half,[
 114   --enable-half           Use OpenEXR's "half" type for color],[
 115         use_openexr_half=$enableval
 116 ],
 117 [
 118         use_openexr_half="no"
 119 ])
 120
 121
 122
 123 AC_ARG_ENABLE(layer-profiling,[
 124   --enable-layer-profiling       Enable layer profiling],[
 125         use_layerprofiling=$enableval
 126 ],
 127 [
 128         use_layerprofiling="no"
 129 ])
 130 if test $use_layerprofiling = "yes" ; then {
 131         AC_DEFINE(SYNFIG_PROFILE_LAYERS,[1],[enable layer profiling])
 132 } ; fi
 133
 134
 135
 136
 137 AC_ARG_WITH(imagemagick,[
 138   --without-imagemagick   Disable support for ImageMagick],[
 139 ],[
 140     AC_CHECK_PROG([imagemagick_convert],[convert],[yes],[no])
 141     with_imagemagick=$imagemagick_convert
 142 ])
 143 if test $with_imagemagick = "no" ; then {
 144         AM_CONDITIONAL(WITH_IMAGEMAGICK,false)
 145 } else {
 146         AM_CONDITIONAL(WITH_IMAGEMAGICK,true)
 147 } ; fi
 148
 149
 150
 151
 152
 153 AC_ARG_WITH(magickpp,[
 154   --without-magickpp        Disable support for Magick++],[
 155 ],[
 156         with_magickpp="yes"
 157 ])
 158 if test $with_magickpp = "yes" ; then {
 159   AC_CHECK_HEADER([Magick++.h],[
 160         MAGICKPP_LIBS="-lMagick++"
 161         AC_DEFINE(HAVE_MAGICKPP,[], [ Define if Magick++ library is available ] )
 162         AC_SUBST(MAGICKPP_LIBS)
 163         AM_CONDITIONAL(HAVE_LIBMAGICKPP,true)
 164         AC_CHECK_LIB(Magick,OptimizeImageTransparency,[
 165                 AC_DEFINE(HAVE_MAGICK_OPTIMIZE,[], [ Define if Magick++ defines OptimizeImageTransparency() ] )
 166                 AM_CONDITIONAL(HAVE_MAGICK_OPTIMIZE,true)
 167         ],[
 168                 AC_MSG_RESULT([ *** OptimizeImageTransparency() not available - need ImageMagick 6.3 or newer ])
 169                 AM_CONDITIONAL(HAVE_MAGICK_OPTIMIZE,false)
 170         ])
 171   ],[
 172         with_magickpp="no"
 173         AC_MSG_RESULT([ *** Magick++ Output target disabled])
 174         TARGET_MAGICKPP="no"
 175         AM_CONDITIONAL(HAVE_LIBMAGICKPP,false)
 176         AM_CONDITIONAL(HAVE_MAGICK_OPTIMIZE,false)
 177   ])
 178 } else {
 179         AM_CONDITIONAL(HAVE_LIBMAGICKPP,false)
 180         AM_CONDITIONAL(HAVE_MAGICK_OPTIMIZE,false)
 181 } ; fi
 182
 183
 184
 185
 186 AC_ARG_WITH(ffmpeg,[
 187   --without-ffmpeg        Disable support for FFMPEG],[
 188 ],[
 189         with_ffmpeg="yes"
 190 ])
 191 if test $with_ffmpeg = "no" ; then {
 192         AM_CONDITIONAL(WITH_FFMPEG,false)
 193 } else {
 194         AM_CONDITIONAL(WITH_FFMPEG,true)
 195 } ; fi
 196
 197
 198
 199
 200 AC_ARG_WITH(vimage,[
 201   --with-vimage        Enable support for apple vImage],[
 202 ],[
 203         with_vimage="no"
 204 ])
 205 if test $with_vimage = "no" ; then {
 206         AM_CONDITIONAL(WITH_VIMAGE,false)
 207 } else {
 208         AM_CONDITIONAL(WITH_VIMAGE,true)
 209         AC_DEFINE(HAS_VIMAGE,[1],[enable apple vImage])
 210         VIMAGE_LIBS="-Wc,-framework -Wc,Accelerate"
 211
 212 } ; fi
 213
 214
 215
 216 AC_ARG_WITH(libdv,[
 217   --without-libdv         Disable support for libdv],[
 218 ],[
 219         with_libdv="yes"
 220 ])
 221 if test $with_libdv = "no" ; then {
 222         AM_CONDITIONAL(WITH_LIBDV,false)
 223 } else {
 224         AM_CONDITIONAL(WITH_LIBDV,true)
 225 } ; fi
 226
 227
 228
 229
 230 # LIBAVCODEC CHECK--------------------
 231
 232 AC_ARG_WITH(libavcodec,[
 233   --without-libavcodec         disable support for libavcodec (Default=auto)],[
 234 ],[
 235         with_libavcodec="yes"
 236 ])
 237
 238 if test $with_libavcodec != "no" ; then {
 239         PKG_CHECK_MODULES(LIBAVCODEC, [libavcodec libavformat],[],[echo no; with_libavcodec="no"])
 240 } ; fi
 241 if test $with_libavcodec = "yes" ; then {
 242         AC_DEFINE(WITH_LIBAVCODEC,[],[enable libavcodec support])
 243         AM_CONDITIONAL(WITH_LIBAVCODEC,true)
 244 } else {
 245         AM_CONDITIONAL(WITH_LIBAVCODEC,false)
 246 } ; fi
 247
 248
 249 if test $with_libavcodec = "yes" ; then {
 250
 251         # Need to check both the new and old locations for the avformat header
 252         # Need to save flags, add avformat flags, check headers and restore flags
 253         ac_save_CPPFLAGS="$CPPFLAGS"
 254         ac_save_CFLAGS="$CFLAGS"
 255         CPPFLAGS="${CPPFLAGS} ${LIBAVCODEC_CFLAGS}"
 256         CFLAGS="${CFLAGS} ${LIBAVCODEC_CFLAGS}"
 257         AC_CHECK_HEADERS(libavformat/avformat.h avformat.h ffmpeg/avformat.h)
 258         CPPFLAGS="${ac_save_CPPFLAGS}"
 259         CFLAGS="${ac_save_CFLAGS}"
 260
 261         AC_ARG_WITH(libswscale,
 262                 [AS_HELP_STRING([--without-libswscale],
 263                         [disable support for libswscale (Default=auto)])],
 264                 [],
 265                 [with_libswscale="yes"]
 266         )
 267
 268         if test $with_libswscale != "no" ; then {
 269                 PKG_CHECK_MODULES(LIBSWSCALE, [libswscale], [], [echo no; with_libswscale="no"])
 270         } ; fi
 271
 272         if test $with_libswscale = "yes" ; then {
 273                 AC_DEFINE(WITH_LIBSWSCALE, [], [enable libswscale support])
 274
 275                 # Need to check both the new and old locations for the swscale header
 276                 # Need to save flags, add swscale flags, check headers and restore flags
 277                 ac_save_CPPFLAGS="$CPPFLAGS"
 278                 ac_save_CFLAGS="$CFLAGS"
 279                 CPPFLAGS="${CPPFLAGS} ${LIBSWSCALE_CFLAGS}"
 280                 CFLAGS="${CFLAGS} ${LIBSWSCALE_CFLAGS}"
 281                 AC_CHECK_HEADERS(libswscale/swscale.h swscale.h ffmpeg/swscale.h)
 282                 CPPFLAGS="${ac_save_CPPFLAGS}"
 283                 CFLAGS="${ac_save_CFLAGS}"
 284         } else {
 285                 AC_CHECK_LIB(avcodec, img_convert,
 286                         [AC_MSG_RESULT([ *** Using deprecated function img_convert.])],
 287                         [AC_MSG_FAILURE([Neither libswscale nor function img_convert was found.])],
 288                         []
 289                 )
 290         } ; fi
 291 } ; fi
 292 AM_CONDITIONAL(WITH_LIBSWSCALE, test "x$with_libswscale" = "xyes")
 293
 294
 295 # FREETYPE2 CHECK--------------------
 296
 297 AC_ARG_WITH(freetype,[
 298   --without-freetype         disable support for freetype (Default=auto)],[
 299 ],[
 300         with_freetype="yes"
 301 ])
 302
 303 if test $with_freetype != "no" ; then {
 304         PKG_CHECK_MODULES(FREETYPE, freetype2,[
 305                 with_freetype="yes"
 306         ],[
 307                 PKG_CHECK_MODULES(FREETYPE, xft,[
 308                         with_freetype="yes"
 309                 ],[
 310                         with_freetype="no"
 311                 ])
 312         ])
 313 } ; fi
 314
 315 if test $with_freetype = "no" ; then {
 316         AM_CONDITIONAL(WITH_FREETYPE,false)
 317 } else {
 318         AM_CONDITIONAL(WITH_FREETYPE,true)
 319 } ; fi
 320
 321
 322 # FONTCONFIG CHECK--------------------
 323
 324 AC_ARG_WITH(fontconfig,[
 325   --without-fontconfig         disable support for fontconfig (Default=auto)],[
 326 ],[
 327         with_fontconfig="yes"
 328 ])
 329
 330 if test $with_fontconfig != "no" ; then {
 331         PKG_CHECK_MODULES(FONTCONFIG, fontconfig,[
 332                 with_fontconfig="yes"
 333         ],[
 334                 with_fontconfig="no"
 335         ])
 336 } ; fi
 337
 338 if test $with_fontconfig = "yes" ; then {
 339         AC_DEFINE(WITH_FONTCONFIG,[],[enable fontconfig support])
 340         AM_CONDITIONAL(WITH_FONTCONFIG,true)
 341 } else {
 342         AM_CONDITIONAL(WITH_FONTCONFIG,false)
 343 } ; fi
 344
 345
 346 # OPENEXR CHECK------------------------
 347 AC_ARG_WITH(openexr,[
 348   --without-openexr        Disable support for ILM's OpenEXR],[
 349 ],[
 350         with_openexr="yes"
 351 ])
 352 if test $with_openexr = "yes" ; then {
 353         PKG_CHECK_MODULES(OPENEXR, OpenEXR,[
 354                 AC_DEFINE(HAVE_OPENEXR,[], [ Define if OpenEXR is available ] )
 355                 AM_CONDITIONAL(WITH_OPENEXR,true)
 356         ],
 357         [
 358                 with_openexr="no"
 359         ])
 360 } ; fi
 361 if test $with_openexr = "no" ; then {
 362         AM_CONDITIONAL(WITH_OPENEXR,false)
 363         use_openexr_half="no"
 364 } ; fi
 365 if test $use_openexr_half = yes ; then {
 366         AC_MSG_RESULT([ ** Using OpenEXR Half.])
 367         CONFIG_DEPS="$CONFIG_DEPS OpenEXR"
 368         CONFIG_CFLAGS="$CONFIG_CFLAGS -DUSE_HALF_TYPE"
 369         OPENEXR_HALF_LIBS="-lHalf"
 370 } else {
 371         OPENEXR_HALF_LIBS=""
 372 } ; fi
 373
 374
 375 # JPEG CHECK (commandline switch) ------------------------
 376 AC_ARG_WITH(jpeg,[
 377   --without-jpeg        Disable support for JPEG],[
 378 ],[
 379         with_jpeg="yes"
 380 ])
 381 if test $with_jpeg = "no" ; then {
 382         AM_CONDITIONAL(WITH_JPEG,false)
 383 } else {
 384         AM_CONDITIONAL(WITH_JPEG,true)
 385 } ; fi
 386
 387
 388
 389
 390
 391 # -- L I B R A R I E S ----------------------------------------
 392
 393 AC_LIB_LTDL
 394
 395 ALL_LINGUAS="es fr"
 396 AM_GNU_GETTEXT([external])
 397 # This is here so autoreconf will run autopoint
 398 AM_GNU_GETTEXT_VERSION([0.14.4])
 399 localedir="$datadir/locale"
 400
 401 PKG_CHECK_MODULES(ETL, [ETL >= 0.04.12],,[
 402         AC_MSG_ERROR([ ** You need to install the ETL (version 0.04.12 or greater).])
 403 ])
 404 CONFIG_DEPS="$CONFIG_DEPS ETL"
 405
 406
 407 PKG_CHECK_MODULES(LIBXMLPP, libxml++-2.6,[
 408         CONFIG_DEPS="$CONFIG_DEPS libxml++-2.6"
 409 ],[
 410         PKG_CHECK_MODULES(LIBXMLPP, libxml++-1.0,[
 411                 CONFIG_DEPS="$CONFIG_DEPS libxml++-1.0"
 412         ],[
 413                 AC_MSG_ERROR([ ** You need to install libxml++, either verison 2.6 or 1.0.])
 414         ])
 415 ])
 416
 417 PKG_CHECK_MODULES(LIBSIGC, [sigc++-2.0],,[
 418         AC_MSG_ERROR([ ** libsigc++-2.0 not found. It is required. You should really install it.])
 419 dnl     PKG_CHECK_MODULES(LIBSIGC, [sigc++-1.2],,[
 420 dnl             AC_MSG_ERROR([ ** At least libsigc++-1.2 is required.])
 421 dnl     ])
 422 ])
 423 CONFIG_DEPS="$CONFIG_DEPS sigc++-2.0"
 424
 425 dnl PKG_CHECK_MODULES(GLIB, glib-2.0,[GLIB="yes"],[GLIB="no"])
 426
 427
 428
 429
 430
 431 TARGET_PNG="yes"
 432 TARGET_MNG="yes"
 433
 434 AC_CHECK_LIB(png, png_write_row,[
 435         PNG_LIBS="-lpng"
 436         AC_DEFINE(HAVE_LIBPNG,[], [ Define if PNG library is available ] )
 437         AC_SUBST(PNG_LIBS)
 438         AM_CONDITIONAL(HAVE_LIBPNG,true)
 439 ],[
 440         AC_CHECK_LIB(png12, png_write_row,[
 441         PNG_LIBS="-lpng12"
 442         AC_DEFINE(HAVE_LIBPNG,[])
 443         AC_SUBST(PNG_LIBS)
 444         AM_CONDITIONAL(HAVE_LIBPNG,true)
 445         ],[
 446                 AC_MSG_RESULT([ *** PNG Output target disabled])
 447                 TARGET_PNG="no"
 448                 AM_CONDITIONAL(HAVE_LIBPNG,false)
 449         ],[-lz -L${exec_prefix}/lib])
 450 ],[-lz -L${exec_prefix}/lib])
 451
 452 AC_CHECK_LIB(mng, mng_initialize,[
 453         MNG_LIBS="-lmng -lz"
 454         AC_DEFINE(HAVE_LIBMNG,[], [ Define if MNG library is available ] )
 455         AC_SUBST(MNG_LIBS)
 456         AM_CONDITIONAL(HAVE_LIBMNG,true)
 457 ],[
 458         AC_MSG_RESULT([ *** MNG Output target disabled])
 459         TARGET_MNG="no"
 460         AM_CONDITIONAL(HAVE_LIBMNG,false)
 461 ],[-lz -L${exec_prefix}/lib])
 462
 463 # check for JPEG availability
 464 if test $with_jpeg = "yes" ; then {
 465         AC_CHECK_LIB(jpeg, jpeg_CreateCompress,[
 466                 JPEG_LIBS="-ljpeg"
 467                 AC_DEFINE(HAVE_LIBJPEG,[], [ Define if JPEG library is available ] )
 468                 AC_SUBST(JPEG_LIBS)
 469                 TARGET_JPEG="yes"
 470                 AM_CONDITIONAL(HAVE_LIBJPEG,true)
 471         ],[
 472                 AC_MSG_RESULT([ *** JPEG Output target disabled])
 473                 TARGET_JPEG="no"
 474                 AM_CONDITIONAL(HAVE_LIBJPEG,false)
 475         ],[
 476                 -L${exec_prefix}/lib
 477         ])
 478 } else {
 479         AC_MSG_RESULT([ *** JPEG Output target disabled])
 480         TARGET_JPEG="no"
 481         AM_CONDITIONAL(HAVE_LIBJPEG,false)
 482 } ; fi
 483
 484
 485
 486 MODULE_DIR='${libdir}/synfig/modules'
 487 moduledir=$libdir/synfig/modules
 488 AC_SUBST(MODULE_DIR)
 489 SYNFIGLIB_DIR=$libdir/synfig
 490 AC_SUBST(SYNFIGLIB_DIR)
 491
 492 # Check for unordered_map or hash_map headers
 493 AC_MSG_CHECKING([for unordered_map<int,int>::const_iterator])
 494 AC_COMPILE_IFELSE([
 495         AC_LANG_PROGRAM([
 496                 [#include <tr1/unordered_map>]
 497         ],[
 498                 [std::tr1::unordered_map<int,int>::const_iterator iter;]
 499         ])],[
 500         AC_MSG_RESULT([yes])
 501         AC_DEFINE([HASH_MAP_CLASS],[HASH_MAP_NAMESPACE::unordered_map],[The template name for unordered maps.])
 502         AC_DEFINE([HASH_MAP_H],[<tr1/unordered_map>],[The header file to include for unordered maps.])
 503         AC_DEFINE([HASH_MAP_NAMESPACE],[std::tr1],[The namespace for unordered maps.])
 504         AC_DEFINE([FUNCTIONAL_H],[<tr1/functional>],[The header file for hash<T>.])
 505         AC_DEFINE([FUNCTIONAL_HASH_ON_STRING],[1],[Define to 1 if hash<T> needs to use T=String rather than T=char* to hash strings.])
 506 ],[
 507         AC_MSG_RESULT([no])
 508         AC_CHECK_HEADERS([ext/hash_map],[
 509                 AC_DEFINE([HASH_MAP_CLASS],[HASH_MAP_NAMESPACE::hash_map],[The template name for unordered maps.])
 510                 AC_DEFINE([HASH_MAP_H],[<ext/hash_map>],[The header file to include for unordered maps.])
 511                 AC_DEFINE([HASH_MAP_NAMESPACE],[__gnu_cxx],[The namespace for unordered maps.])
 512                 AC_DEFINE([FUNCTIONAL_H],[<ext/functional>],[The header file for hash<T>.])
 513         ],[
 514                 AC_MSG_ERROR([C++ compiler does not seem to support unordered containers])
 515         ])
 516 ])
 517
 518 # Check for unordered_set or hash_set headers
 519 AC_MSG_CHECKING([for unordered_set<int,int>::const_iterator])
 520 AC_COMPILE_IFELSE([
 521         AC_LANG_PROGRAM([
 522                 [#include <tr1/unordered_set>]
 523         ],[
 524                 [std::tr1::unordered_set<int,int>::const_iterator iter;]
 525         ])],[
 526         AC_MSG_RESULT([yes])
 527         AC_DEFINE([HASH_SET_CLASS],[HASH_SET_NAMESPACE::unordered_set],[The template name for unordered sets.])
 528         AC_DEFINE([HASH_SET_H],[<tr1/unordered_set>],[The header file to include for unordered sets.])
 529         AC_DEFINE([HASH_SET_NAMESPACE],[std::tr1],[The namespace for unordered sets.])
 530 ],[
 531         AC_MSG_RESULT([no])
 532         AC_CHECK_HEADERS([ext/hash_set],[
 533                 AC_DEFINE([HASH_SET_CLASS],[HASH_SET_NAMESPACE::hash_set],[The template name for unordered sets.])
 534                 AC_DEFINE([HASH_SET_H],[<ext/hash_set>],[The header file to include for unordered sets.])
 535                 AC_DEFINE([HASH_SET_NAMESPACE],[__gnu_cxx],[The namespace for unordered sets.])
 536         ],[
 537                 AC_MSG_ERROR([C++ compiler does not seem to support unordered containers])
 538         ])
 539 ])
 540
 541
 542
 543
 544
 545 AC_CHECK_HEADERS(signal.h termios.h sys/errno.h)
 546
 547
 548 case "$host" in
 549         *mingw* | *cygwin*)
 550                 AM_CONDITIONAL(WIN32_PKG, true)
 551                 AM_CONDITIONAL(MACOSX_PKG, false)
 552         ;;
 553         *darwin*)
 554                 AM_CONDITIONAL(WIN32_PKG, false)
 555                 AM_CONDITIONAL(MACOSX_PKG, true)
 556         ;;
 557         *)
 558                 AM_CONDITIONAL(WIN32_PKG, false)
 559                 AM_CONDITIONAL(MACOSX_PKG, false)
 560         ;;
 561 esac
 562
 563
 564
 565 # -- H E A D E R S --------------------------------------------
 566
 567 AC_HEADER_SYS_WAIT
 568 AC_CHECK_HEADERS([process.h io.h fcntl.h])
 569
 570 # -- T Y P E S & S T R U C T S --------------------------------
 571
 572 # -- F U N C T I O N S ----------------------------------------
 573
 574 dnl AC_CHECK_FUNCS([floor pow sqrt],[],[
 575 dnl     AC_MSG_ERROR([ ** Could not find proper math functions.])
 576 dnl ])
 577
 578 AC_CHECK_FUNCS([fork])
 579 AC_CHECK_FUNCS([kill])
 580 AC_CHECK_FUNCS([pipe])
 581 AC_CHECK_FUNCS([waitpid])
 582
 583 AC_CHECK_FUNCS(
 584         [isnan],
 585         [],
 586         [
 587                 AC_CHECK_FUNCS(
 588                         [_isnan]
 589                 )
 590         ]
 591 )
 592
 593 AC_CHECK_FUNCS(
 594         [isnanf],
 595         [],
 596         [
 597                 AC_CHECK_FUNCS(
 598                         [_isnanf]
 599                 )
 600         ]
 601 )
 602
 603 AC_CHECK_FUNCS(
 604         [floorl],
 605         [],
 606         [
 607                 AC_CHECK_FUNCS(
 608                         [_floorl]
 609                 )
 610         ]
 611 )
 612
 613 AC_CHECK_LIB([pthread],[pthread_create])
 614
 615 # -- O U T P U T ----------------------------------------------
 616
 617 AC_SUBST(CFLAGS)
 618 AC_SUBST(CXXFLAGS)
 619 AC_SUBST(CPPFLAGS)
 620 AC_SUBST(LDFLAGS)
 621
 622 # this line is required for libtool 1.5.26 but must not be present for libtool 2.2.4...
 623 AC_CONFIG_SUBDIRS(libltdl)
 624
 625 CONFIG_LIBS="-lsynfig"
 626 CONFIG_CFLAGS="$CONFIG_CFLAGS"
 627 AC_SUBST(CONFIG_LIBS)
 628 AC_SUBST(CONFIG_CFLAGS)
 629 AC_SUBST(CONFIG_DEPS)
 630 AC_SUBST(ETL_CFLAGS)
 631
 632 SYNFIG_LIBS="$VIMAGE_LIBS $LIBXMLPP_LIBS $ETL_LIBS $LIBSIGC_LIBS $LTLIBINTL"
 633 SYNFIG_CFLAGS="$LIBXMLPP_CFLAGS $ETL_CFLAGS $LIBSIGC_CFLAGS $CONFIG_CFLAGS -DSYNFIG_NO_DEPRECATED -DLOCALEDIR=\\\"$localedir\\\""
 634
 635 CONFIG_CFLAGS="`echo $CONFIG_CFLAGS | sed s/-mno-cygwin//g | sed s/-mwindows//g`"
 636 SYNFIG_CFLAGS="`echo $SYNFIG_CFLAGS | sed s/-mno-cygwin//g | sed s/-mwindows//g`"
 637 SYNFIG_LIBS="`echo $SYNFIG_LIBS | sed s/-mno-cygwin//g | sed s/-mwindows//g`"
 638
 639 AC_SUBST(LIBADD_DL)
 640
 641 AC_SUBST(SYNFIG_LIBS)
 642 AC_SUBST(SYNFIG_CFLAGS)
 643 AC_SUBST(OPENEXR_HALF_LIBS)
 644
 645 AC_SUBST(API_VERSION)
 646
 647 synfigincludedir=$includedir/synfig-$API_VERSION
 648 AC_SUBST(synfigincludedir)
 649
 650 AC_CONFIG_FILES([synfig-config
 651 synfig.pc
 652 doxygen.cfg
 653 Makefile
 654 po/Makefile.in
 655 src/Makefile
 656 src/synfig/Makefile
 657 src/modules/Makefile
 658 src/modules/lyr_freetype/Makefile
 659 src/modules/lyr_std/Makefile
 660 src/modules/mod_bmp/Makefile
 661 src/modules/mod_dv/Makefile
 662 src/modules/mod_ffmpeg/Makefile
 663 src/modules/mod_filter/Makefile
 664 src/modules/mod_geometry/Makefile
 665 src/modules/mod_gif/Makefile
 666 src/modules/mod_gradient/Makefile
 667 src/modules/mod_imagemagick/Makefile
 668 src/modules/mod_jpeg/Makefile
 669 src/modules/mod_libavcodec/Makefile
 670 src/modules/mod_magickpp/Makefile
 671 src/modules/mod_mng/Makefile
 672 src/modules/mod_noise/Makefile
 673 src/modules/mod_openexr/Makefile
 674 src/modules/mod_particle/Makefile
 675 src/modules/mod_png/Makefile
 676 src/modules/mod_ppm/Makefile
 677 src/modules/mod_yuv420p/Makefile
 678 src/tool/Makefile
 679 src/modules/synfig_modules.cfg
 680 examples/walk/Makefile
 681 examples/Makefile
 682 win32inst.nsi
 683 pkg-info/macosx/synfig-core.info
 684 ])
 685 ## src/modules/trgt_mpg/Makefile
 686 ## src/modules/mptr_mplayer/Makefile
 687 AC_OUTPUT
 688
 689 # -- S U M M A R Y --------------------------------------------
 690
 691 echo "
 692 $PACKAGE_NAME v.$VERSION
 693 Configuration Summary
 694 - - - - - -
 695
 696 Install Prefix -------------------> $prefix
 697 Module directory -----------------> $moduledir
 698 Build Platform -------------------> $build
 699 Host Platform --------------------> $host
 700 Arc Profiling --------------------> $profile_arcs
 701 GProf Profiling ------------------> $profiling
 702 Debug Mode -----------------------> $debug ($debug_flags)
 703 Optimization ---------------------> $optimization
 704 PNG output target support --------> $TARGET_PNG
 705 MNG output target support --------> $TARGET_MNG
 706 JPEG output target support -------> $TARGET_JPEG
 707 ETL_CFLAGS -----------------------> $ETL_CFLAGS
 708 FreeType2 ------------------------> $with_freetype
 709 fontconfig -----------------------> $with_fontconfig
 710 libavcodec -----------------------> $with_libavcodec
 711 libswscale -----------------------> $with_libswscale
 712 vImage ---------------------------> $with_vimage
 713 ImageMagick ----------------------> $with_imagemagick
 714 Magick++ -------------------------> $with_magickpp
 715 FFMPEG ---------------------------> $with_ffmpeg
 716 libdv ----------------------------> $with_libdv
 717 OpenEXR --------------------------> $with_openexr
 718 Using OpenEXR's \"half\" type ------> $use_openexr_half
 719
 720 "'$'"CXX -----------------------------> '$CXX'
 721 "'$'"CXXFLAGS ------------------------> '$CXXFLAGS'
 722 "'$'"SYNFIG_LIBS ---------------------> '$SYNFIG_LIBS'
 723 "'$'"LIBXMLPP_LIBS -------------------> '$LIBXMLPP_LIBS'
 724 "'$'"ETL_LIBS ------------------------> '$ETL_LIBS'
 725 "'$'"LIBSIGC_LIBS --------------------> '$LIBSIGC_LIBS'
 726 "'$'"SYNFIG_CFLAGS -------------------> '$SYNFIG_CFLAGS'
 727 "'$'"LIBADD_DL -----------------------> '$LIBADD_DL'
 728 "