synfig-studio/trunk/configure.ac

   1 # $Id$
   2
   3 # -- I N I T --------------------------------------------------
   4
   5 AC_INIT([Synfig Studio],[0.61.07],[http://synfig.org/Bugs],[synfigstudio])
   6 AC_REVISION
   7
   8 AC_CONFIG_AUX_DIR(config)
   9 AM_CONFIG_HEADER(config.h)
  10 AC_CANONICAL_HOST
  11 dnl AC_CANONICAL_TARGET
  12
  13 AM_INIT_AUTOMAKE
  14 AM_MAINTAINER_MODE
  15
  16 API_VERSION=0.0
  17
  18 # -- V A R I A B L E S ----------------------------------------
  19
  20 SVN_REPOSITORY=http://svn.voria.com/code/synfig-studio
  21
  22 # -- P R O G R A M S ------------------------------------------
  23
  24 AC_PROG_CC
  25 AC_GNU_SOURCE
  26 AC_PROG_CXX
  27 AC_PROG_CPP
  28 AC_PROG_CXXCPP
  29 AC_PROG_INSTALL
  30
  31 AC_LANG_CPLUSPLUS
  32
  33
  34 AC_ARG_DEBUG
  35
  36 case "$debug" in
  37         yes)
  38                 AC_DEFINE(SHOW_EXTRA_INFO,[],[Show extra info in the about dialog])
  39         ;;
  40 esac
  41
  42 AC_ARG_OPTIMIZATION
  43 AC_ARG_WARNINGS
  44 AC_ARG_PROFILE_ARCS
  45 AC_ARG_BRANCH_PROBABILITIES
  46 AC_ARG_PROFILING
  47
  48 AC_ARG_ENABLE(g5opt,[
  49   --enable-g5opt           enable optimizations specific to G5 proc],[
  50     G5OPTFLAGS="-mpowerpc-gpopt -mno-multiple -mno-update -mcpu=970  -mtune=970 -falign-loops=16 -falign-functions=16"
  51 ],
  52 [
  53     G5OPTFLAGS=
  54 ])
  55
  56 AC_WIN32_QUIRKS
  57
  58 AC_LIBTOOL_WIN32_DLL
  59 AC_LIBTOOL_DLOPEN
  60 AC_DISABLE_STATIC
  61 AC_ENABLE_SHARED
  62 AC_PROG_LIBTOOL
  63 AC_SUBST(LIBTOOL_DEPS)
  64 AC_LIBTOOL_PATCH
  65
  66 ## FIXME: add i18n for .desktop and other non-compiled files
  67 ## AM_GLIB_GNU_GETTEXT([external])
  68 ## AC_PROG_INTLTOOL(0.11)
  69 ALL_LINGUAS="fr es"
  70 AM_GNU_GETTEXT([external])
  71 # This is here so autoreconf will run autopoint
  72 AM_GNU_GETTEXT_VERSION([0.14.4])
  73
  74 case "$host" in
  75         *mingw* | *cygwin*)
  76                 AM_CONDITIONAL(WIN32_PKG, true)
  77                 AM_CONDITIONAL(MACOSX_PKG, false)
  78         ;;
  79         *darwin*)
  80                 AM_CONDITIONAL(WIN32_PKG, false)
  81                 AM_CONDITIONAL(MACOSX_PKG, true)
  82         ;;
  83         *)
  84                 AM_CONDITIONAL(WIN32_PKG, false)
  85                 AM_CONDITIONAL(MACOSX_PKG, false)
  86         ;;
  87 esac
  88 # -- L I B R A R I E S ----------------------------------------
  89
  90 PKG_CHECK_MODULES(GTKMM, gtkmm-2.4 gthread-2.0,[],[
  91         AC_MSG_ERROR([ ** Gtkmm-2.4 Is a required library, aborting.])
  92 ])
  93 AC_SUBST(GTKMM_CFLAGS)
  94 AC_SUBST(GTKMM_LIBS)
  95
  96 PKG_CHECK_MODULES(SYNFIG, [synfig >= 0.61.07] [ETL >= 0.04.10] sigc++-2.0,,[
  97         AC_MSG_ERROR([ ** Unable to set up dependent libraries (synfig >= 0.61.07, ETL >= 0.04.10)])
  98 ])
  99 AC_SUBST(SYNFIG_CFLAGS)
 100 AC_SUBST(SYNFIG_LIBS)
 101
 102 windowsys="gtkmm"
 103 AC_DEFINE(STUDIO_WINSYS_H,"gtkmm/winsys.h",[blah])
 104 AM_CONDITIONAL(WINDOWSYS_GTKMM,true)
 105
 106 AC_ARG_WITH(userdir,[
 107   --with-userdir=(dirname)         Relative path to user directory],[
 108 ],[
 109 case "$host" in
 110         *mingw* | *cygwin*)
 111                 with_userdir="Synfig"
 112         ;;
 113         *darwin*)
 114                 with_userdir="Library/Synfig"
 115         ;;
 116         *)
 117                 with_userdir=".synfig"
 118         ;;
 119 esac
 120 ])
 121 AC_DEFINE_UNQUOTED(SYNFIG_USER_APP_DIR,"$with_userdir",[Synfig User Data Directory])
 122
 123 # --- FMOD CHECK -------------
 124 AC_ARG_WITH(libfmod,[
 125   --with-libfmod         Enable support for FMOD],[
 126 ],[
 127         AC_CHECK_LIB(fmod, FSOUND_Init,[
 128                 with_libfmod="yes"
 129         ],[
 130                 with_libfmod="no"
 131         ])
 132 ])
 133 if test $with_libfmod = "yes" ; then {
 134         AM_CONDITIONAL(WITH_FMOD,true)
 135         FMOD_LIBS="/usr/lib/libfmod.so"
 136         AC_DEFINE(WITH_FMOD,"I'm here damnit",[blah])
 137 } else {
 138         AM_CONDITIONAL(WITH_FMOD,false)
 139         FMOD_LIBS=
 140 } ; fi
 141
 142 # Check for unordered_map or hash_map headers
 143 AC_MSG_CHECKING([for unordered_map<int,int>::const_iterator])
 144 AC_COMPILE_IFELSE([
 145         AC_LANG_PROGRAM([
 146                 [#include <tr1/unordered_map>]
 147         ],[
 148                 [std::tr1::unordered_map<int,int>::const_iterator iter;]
 149         ])],[
 150         AC_MSG_RESULT([yes])
 151         AC_DEFINE([HASH_MAP_CLASS],[HASH_MAP_NAMESPACE::unordered_map],[The template name for unordered maps.])
 152         AC_DEFINE([HASH_MAP_H],[<tr1/unordered_map>],[The header file to include for unordered maps.])
 153         AC_DEFINE([HASH_MAP_NAMESPACE],[std::tr1],[The namespace for unordered maps.])
 154         AC_DEFINE([FUNCTIONAL_H],[<tr1/functional>],[The header file for hash<T>.])
 155         AC_DEFINE([FUNCTIONAL_HASH_ON_STRING],[1],[Define to 1 if hash<T> needs to use T=String rather than T=char* to hash strings.])
 156 ],[
 157         AC_MSG_RESULT([no])
 158         AC_CHECK_HEADERS([ext/hash_map],[
 159                 AC_DEFINE([HASH_MAP_CLASS],[HASH_MAP_NAMESPACE::hash_map],[The template name for unordered maps.])
 160                 AC_DEFINE([HASH_MAP_H],[<ext/hash_map>],[The header file to include for unordered maps.])
 161                 AC_DEFINE([HASH_MAP_NAMESPACE],[__gnu_cxx],[The namespace for unordered maps.])
 162                 AC_DEFINE([FUNCTIONAL_H],[<ext/functional>],[The header file for hash<T>.])
 163         ],[
 164                 AC_MSG_ERROR([C++ compiler does not seem to support unordered containers])
 165         ])
 166 ])
 167
 168 # Check for unordered_set or hash_set headers
 169 AC_MSG_CHECKING([for unordered_set<int,int>::const_iterator])
 170 AC_COMPILE_IFELSE([
 171         AC_LANG_PROGRAM([
 172                 [#include <tr1/unordered_set>]
 173         ],[
 174                 [std::tr1::unordered_set<int,int>::const_iterator iter;]
 175         ])],[
 176         AC_MSG_RESULT([yes])
 177         AC_DEFINE([HASH_SET_CLASS],[HASH_SET_NAMESPACE::unordered_set],[The template name for unordered sets.])
 178         AC_DEFINE([HASH_SET_H],[<tr1/unordered_set>],[The header file to include for unordered sets.])
 179         AC_DEFINE([HASH_SET_NAMESPACE],[std::tr1],[The namespace for unordered sets.])
 180 ],[
 181         AC_MSG_RESULT([no])
 182         AC_CHECK_HEADERS([ext/hash_set],[
 183                 AC_DEFINE([HASH_SET_CLASS],[HASH_SET_NAMESPACE::hash_set],[The template name for unordered sets.])
 184                 AC_DEFINE([HASH_SET_H],[<ext/hash_set>],[The header file to include for unordered sets.])
 185                 AC_DEFINE([HASH_SET_NAMESPACE],[__gnu_cxx],[The namespace for unordered sets.])
 186         ],[
 187                 AC_MSG_ERROR([C++ compiler does not seem to support unordered containers])
 188         ])
 189 ])
 190
 191 # -- H E A D E R S --------------------------------------------
 192
 193 AC_CHECK_HEADERS([unistd.h signal.h fcntl.h])
 194 AC_CHECK_HEADERS([sys/types.h sys/wait.h sys/stat.h sys/time.h sys/resource.h sys/errno.h])
 195
 196 # -- T Y P E S & S T R U C T S --------------------------------
 197
 198 # -- F U N C T I O N S ----------------------------------------
 199
 200 AC_CHECK_FUNCS([fork])
 201 AC_CHECK_FUNCS([kill])
 202 AC_CHECK_FUNCS([pipe])
 203 AC_CHECK_FUNCS([setpriority mkfifo stat])
 204
 205 # -- A R G U M E N T S ----------------------------------------
 206
 207 # -- O U T P U T ----------------------------------------------
 208
 209 AC_SUBST(CFLAGS)
 210 AC_SUBST(CPPFLAGS)
 211 AC_SUBST(CXXFLAGS)
 212 AC_SUBST(LDFLAGS)
 213 AC_SUBST(SVN_REPOSITORY)
 214
 215 AC_SUBST(API_VERSION)
 216
 217 # fmod stuff...
 218 AC_SUBST(FMOD_LIBS)
 219
 220 imageext=png
 221 AC_SUBST(imageext)
 222
 223 imagedir="${datadir}/pixmaps/synfigstudio"
 224 AC_SUBST(imagedir)
 225
 226 AC_OUTPUT(
 227 Makefile
 228 build_tools/Makefile
 229 doxygen.cfg
 230 po/Makefile.in
 231 synfigstudio.desktop
 232 synfigstudio.mime
 233 synfigstudio.keys
 234 synfigstudio.xml
 235 synfigstudio-thumbnailer.schemas
 236 src/Makefile
 237 src/gtkmm/Makefile
 238 src/synfigapp/Makefile
 239 images/Makefile
 240 win32inst.nsi
 241 pkg-info/macosx/synfig-studio.info
 242 )
 243
 244 # -- S U M M A R Y --------------------------------------------
 245
 246 echo "
 247 $PACKAGE_NAME v.$VERSION
 248 Configuration Summary
 249 - - - - - -
 250
 251 Install Prefix -------------------> $prefix
 252 Host Platform --------------------> $host
 253 Icon Format ----------------------> $imageext
 254 Debug Mode -----------------------> $debug
 255 Profiling Mode -------------------> $profiling
 256 Optimizations --------------------> $optimization
 257 Window System --------------------> $windowsys
 258 FMOD Enabled ---------------------> $with_libfmod
 259
 260 "'$'"CXX ------------------------------> '$CXX'
 261 "'$'"CXXFLAGS -------------------------> '$CXXFLAGS'
 262 "'$'"LDFLAGS --------------------------> '$LDFLAGS'
 263 "'$'"SYNFIG_CFLAGS ---------------------> '$SYNFIG_CFLAGS'
 264 "'$'"SYNFIG_LIBS -----------------------> '$SYNFIG_LIBS'
 265 "'$'"GTKMM_CFLAGS ---------------------> '$GTKMM_CFLAGS'
 266 "'$'"GTKMM_LIBS -----------------------> '$GTKMM_LIBS'
 267 "