synfig-studio/trunk/configure.ac

   1 # $Id$
   2
   3 # -- I N I T --------------------------------------------------
   4
   5 AC_INIT([Synfig Studio],[0.61.07],[http://synfig.org/Bugs],[synfigstudio])
   6 AC_REVISION
   7
   8 AC_CONFIG_AUX_DIR(config)
   9 AM_CONFIG_HEADER(config.h)
  10 AC_CANONICAL_HOST
  11 dnl AC_CANONICAL_TARGET
  12
  13 AM_INIT_AUTOMAKE
  14 AM_MAINTAINER_MODE
  15
  16 API_VERSION=0.0
  17
  18 # -- V A R I A B L E S ----------------------------------------
  19
  20 SVN_REPOSITORY=http://svn.voria.com/code/synfig-studio
  21
  22 # -- P R O G R A M S ------------------------------------------
  23
  24 AC_PROG_CC
  25 AC_GNU_SOURCE
  26 AC_PROG_CXX
  27 AC_PROG_CPP
  28 AC_PROG_CXXCPP
  29 AC_PROG_INSTALL
  30
  31 AC_LANG_CPLUSPLUS
  32
  33
  34 AC_ARG_DEBUG
  35
  36 case "$debug" in
  37         yes)
  38                 AC_DEFINE(SHOW_EXTRA_INFO,[],[Show extra info in the about dialog])
  39         ;;
  40 esac
  41
  42 AC_ARG_OPTIMIZATION
  43 AC_ARG_WARNINGS
  44 AC_ARG_PROFILE_ARCS
  45 AC_ARG_BRANCH_PROBABILITIES
  46 AC_ARG_PROFILING
  47
  48 AC_ARG_ENABLE(g5opt,[
  49   --enable-g5opt           enable optimizations specific to G5 proc],[
  50     G5OPTFLAGS="-mpowerpc-gpopt -mno-multiple -mno-update -mcpu=970  -mtune=970 -falign-loops=16 -falign-functions=16"
  51 ],
  52 [
  53     G5OPTFLAGS=
  54 ])
  55
  56 AC_WIN32_QUIRKS
  57
  58 AC_LIBTOOL_WIN32_DLL
  59 AC_LIBTOOL_DLOPEN
  60 AC_DISABLE_STATIC
  61 AC_ENABLE_SHARED
  62 AC_PROG_LIBTOOL
  63 AC_SUBST(LIBTOOL_DEPS)
  64 AC_LIBTOOL_PATCH
  65
  66 ## FIXME: add i18n for .desktop and other non-compiled files
  67 ## AM_GLIB_GNU_GETTEXT([external])
  68 ## AC_PROG_INTLTOOL(0.11)
  69 ALL_LINGUAS="fr es"
  70 AM_GNU_GETTEXT([external])
  71 # This is here so autoreconf will run autopoint
  72 AM_GNU_GETTEXT_VERSION([0.14.4])
  73
  74 case "$host" in
  75         *mingw* | *cygwin*)
  76                 AM_CONDITIONAL(WIN32_PKG, true)
  77                 AM_CONDITIONAL(MACOSX_PKG, false)
  78         ;;
  79         *darwin*)
  80                 AM_CONDITIONAL(WIN32_PKG, false)
  81                 AM_CONDITIONAL(MACOSX_PKG, true)
  82         ;;
  83         *)
  84                 AM_CONDITIONAL(WIN32_PKG, false)
  85                 AM_CONDITIONAL(MACOSX_PKG, false)
  86         ;;
  87 esac
  88 # -- L I B R A R I E S ----------------------------------------
  89
  90 PKG_CHECK_MODULES(GTKMM, gtkmm-2.4 gthread-2.0,[
  91         AC_MSG_CHECKING([for Gtk::AboutDialog::set_program_name])
  92         CXXFLAGS="$GTKMM_CFLAGS"
  93         AC_COMPILE_IFELSE(
  94                 [
  95                         AC_LANG_PROGRAM([
  96                                 [#include <gtkmm/aboutdialog.h>]
  97                         ],[
  98                                 [Gtk::AboutDialog about; about.set_program_name(PACKAGE_NAME)]
  99                         ])
 100                 ],[
 101                         AC_MSG_RESULT([yes])
 102                         AC_DEFINE(HAVE_GTK_ABOUTDIALOG_SET_PROGRAM_NAME,[],[Define if GTKmm provides Gtk::AboutDialog::set_program_name()] )
 103                         AM_CONDITIONAL(HAVE_GTK_ABOUTDIALOG_SET_PROGRAM_NAME,true)
 104                 ],[
 105                         AC_MSG_RESULT([no])
 106                         AM_CONDITIONAL(HAVE_GTK_ABOUTDIALOG_SET_PROGRAM_NAME,false)
 107                 ]
 108         )
 109 ],[
 110         AC_MSG_ERROR([ ** Gtkmm-2.4 Is a required library, aborting.])
 111 ])
 112 AC_SUBST(GTKMM_CFLAGS)
 113 AC_SUBST(GTKMM_LIBS)
 114
 115 PKG_CHECK_MODULES(SYNFIG, [synfig >= 0.61.07] [ETL >= 0.04.10] sigc++-2.0,,[
 116         AC_MSG_ERROR([ ** Unable to set up dependent libraries (synfig >= 0.61.07, ETL >= 0.04.10)])
 117 ])
 118 AC_SUBST(SYNFIG_CFLAGS)
 119 AC_SUBST(SYNFIG_LIBS)
 120
 121 windowsys="gtkmm"
 122 AC_DEFINE(STUDIO_WINSYS_H,"gtkmm/winsys.h",[blah])
 123 AM_CONDITIONAL(WINDOWSYS_GTKMM,true)
 124
 125 AC_ARG_WITH(userdir,[
 126   --with-userdir=(dirname)         Relative path to user directory],[
 127 ],[
 128 case "$host" in
 129         *mingw* | *cygwin*)
 130                 with_userdir="Synfig"
 131         ;;
 132         *darwin*)
 133                 with_userdir="Library/Synfig"
 134         ;;
 135         *)
 136                 with_userdir=".synfig"
 137         ;;
 138 esac
 139 ])
 140 AC_DEFINE_UNQUOTED(SYNFIG_USER_APP_DIR,"$with_userdir",[Synfig User Data Directory])
 141
 142 # --- FMOD CHECK -------------
 143 AC_ARG_WITH(libfmod,[
 144   --with-libfmod         Enable support for FMOD],[
 145 ],[
 146         AC_CHECK_LIB(fmod, FSOUND_Init,[
 147                 with_libfmod="yes"
 148         ],[
 149                 with_libfmod="no"
 150         ])
 151 ])
 152 if test $with_libfmod = "yes" ; then {
 153         AM_CONDITIONAL(WITH_FMOD,true)
 154         FMOD_LIBS="/usr/lib/libfmod.so"
 155         AC_DEFINE(WITH_FMOD,"I'm here damnit",[blah])
 156 } else {
 157         AM_CONDITIONAL(WITH_FMOD,false)
 158         FMOD_LIBS=
 159 } ; fi
 160
 161 # Check for unordered_map or hash_map headers
 162 AC_MSG_CHECKING([for unordered_map<int,int>::const_iterator])
 163 AC_COMPILE_IFELSE([
 164         AC_LANG_PROGRAM([
 165                 [#include <tr1/unordered_map>]
 166         ],[
 167                 [std::tr1::unordered_map<int,int>::const_iterator iter;]
 168         ])],[
 169         AC_MSG_RESULT([yes])
 170         AC_DEFINE([HASH_MAP_CLASS],[HASH_MAP_NAMESPACE::unordered_map],[The template name for unordered maps.])
 171         AC_DEFINE([HASH_MAP_H],[<tr1/unordered_map>],[The header file to include for unordered maps.])
 172         AC_DEFINE([HASH_MAP_NAMESPACE],[std::tr1],[The namespace for unordered maps.])
 173         AC_DEFINE([FUNCTIONAL_H],[<tr1/functional>],[The header file for hash<T>.])
 174         AC_DEFINE([FUNCTIONAL_HASH_ON_STRING],[1],[Define to 1 if hash<T> needs to use T=String rather than T=char* to hash strings.])
 175 ],[
 176         AC_MSG_RESULT([no])
 177         AC_CHECK_HEADERS([ext/hash_map],[
 178                 AC_DEFINE([HASH_MAP_CLASS],[HASH_MAP_NAMESPACE::hash_map],[The template name for unordered maps.])
 179                 AC_DEFINE([HASH_MAP_H],[<ext/hash_map>],[The header file to include for unordered maps.])
 180                 AC_DEFINE([HASH_MAP_NAMESPACE],[__gnu_cxx],[The namespace for unordered maps.])
 181                 AC_DEFINE([FUNCTIONAL_H],[<ext/functional>],[The header file for hash<T>.])
 182         ],[
 183                 AC_MSG_ERROR([C++ compiler does not seem to support unordered containers])
 184         ])
 185 ])
 186
 187 # Check for unordered_set or hash_set headers
 188 AC_MSG_CHECKING([for unordered_set<int,int>::const_iterator])
 189 AC_COMPILE_IFELSE([
 190         AC_LANG_PROGRAM([
 191                 [#include <tr1/unordered_set>]
 192         ],[
 193                 [std::tr1::unordered_set<int,int>::const_iterator iter;]
 194         ])],[
 195         AC_MSG_RESULT([yes])
 196         AC_DEFINE([HASH_SET_CLASS],[HASH_SET_NAMESPACE::unordered_set],[The template name for unordered sets.])
 197         AC_DEFINE([HASH_SET_H],[<tr1/unordered_set>],[The header file to include for unordered sets.])
 198         AC_DEFINE([HASH_SET_NAMESPACE],[std::tr1],[The namespace for unordered sets.])
 199 ],[
 200         AC_MSG_RESULT([no])
 201         AC_CHECK_HEADERS([ext/hash_set],[
 202                 AC_DEFINE([HASH_SET_CLASS],[HASH_SET_NAMESPACE::hash_set],[The template name for unordered sets.])
 203                 AC_DEFINE([HASH_SET_H],[<ext/hash_set>],[The header file to include for unordered sets.])
 204                 AC_DEFINE([HASH_SET_NAMESPACE],[__gnu_cxx],[The namespace for unordered sets.])
 205         ],[
 206                 AC_MSG_ERROR([C++ compiler does not seem to support unordered containers])
 207         ])
 208 ])
 209
 210 # -- H E A D E R S --------------------------------------------
 211
 212 AC_CHECK_HEADERS([unistd.h signal.h fcntl.h])
 213 AC_CHECK_HEADERS([sys/types.h sys/wait.h sys/stat.h sys/time.h sys/resource.h sys/errno.h])
 214
 215 # -- T Y P E S & S T R U C T S --------------------------------
 216
 217 # -- F U N C T I O N S ----------------------------------------
 218
 219 AC_CHECK_FUNCS([fork])
 220 AC_CHECK_FUNCS([kill])
 221 AC_CHECK_FUNCS([pipe])
 222 AC_CHECK_FUNCS([setpriority mkfifo stat])
 223
 224 # -- A R G U M E N T S ----------------------------------------
 225
 226 # -- O U T P U T ----------------------------------------------
 227
 228 AC_SUBST(CFLAGS)
 229 AC_SUBST(CPPFLAGS)
 230 AC_SUBST(CXXFLAGS)
 231 AC_SUBST(LDFLAGS)
 232 AC_SUBST(SVN_REPOSITORY)
 233
 234 AC_SUBST(API_VERSION)
 235
 236 # fmod stuff...
 237 AC_SUBST(FMOD_LIBS)
 238
 239 imageext=png
 240 AC_SUBST(imageext)
 241
 242 imagedir="${datadir}/pixmaps/synfigstudio"
 243 AC_SUBST(imagedir)
 244
 245 AC_OUTPUT(
 246 Makefile
 247 build_tools/Makefile
 248 doxygen.cfg
 249 po/Makefile.in
 250 synfigstudio.desktop
 251 synfigstudio.mime
 252 synfigstudio.keys
 253 synfigstudio.xml
 254 synfigstudio-thumbnailer.schemas
 255 src/Makefile
 256 src/gtkmm/Makefile
 257 src/synfigapp/Makefile
 258 images/Makefile
 259 win32inst.nsi
 260 pkg-info/macosx/synfig-studio.info
 261 )
 262
 263 # -- S U M M A R Y --------------------------------------------
 264
 265 echo "
 266 $PACKAGE_NAME v.$VERSION
 267 Configuration Summary
 268 - - - - - -
 269
 270 Install Prefix -------------------> $prefix
 271 Host Platform --------------------> $host
 272 Icon Format ----------------------> $imageext
 273 Debug Mode -----------------------> $debug
 274 Profiling Mode -------------------> $profiling
 275 Optimizations --------------------> $optimization
 276 Window System --------------------> $windowsys
 277 FMOD Enabled ---------------------> $with_libfmod
 278
 279 "'$'"CXX ------------------------------> '$CXX'
 280 "'$'"CXXFLAGS -------------------------> '$CXXFLAGS'
 281 "'$'"LDFLAGS --------------------------> '$LDFLAGS'
 282 "'$'"SYNFIG_CFLAGS ---------------------> '$SYNFIG_CFLAGS'
 283 "'$'"SYNFIG_LIBS -----------------------> '$SYNFIG_LIBS'
 284 "'$'"GTKMM_CFLAGS ---------------------> '$GTKMM_CFLAGS'
 285 "'$'"GTKMM_LIBS -----------------------> '$GTKMM_LIBS'
 286 "