X-Git-Url: https://git.pterodactylus.net/?a=blobdiff_plain;f=media-gfx%2Finkscape%2Finkscape-0.47.ebuild;fp=media-gfx%2Finkscape%2Finkscape-0.47.ebuild;h=b4f5ea426c2a58652ddec9dc3cc4a2e4fc0ae625;hb=a28f218a462686b14e032e6363d3334257f8fe0b;hp=0000000000000000000000000000000000000000;hpb=e151a00f8db87daa5b5d5d4e8b20a0238c1c828e;p=overlay.git

diff --git a/media-gfx/inkscape/inkscape-0.47.ebuild b/media-gfx/inkscape/inkscape-0.47.ebuild
new file mode 100644
index 0000000..b4f5ea4
--- /dev/null
+++ b/media-gfx/inkscape/inkscape-0.47.ebuild
@@ -0,0 +1,92 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/inkscape/inkscape-0.47.ebuild,v 1.7 2010/01/07 18:14:56 josejx Exp $
+
+EAPI=2
+inherit base gnome2
+
+MY_P="${P/_/}"
+S="${WORKDIR}/${MY_P}"
+SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"
+
+DESCRIPTION="A SVG based generic vector-drawing program"
+HOMEPAGE="http://www.inkscape.org/"
+
+SLOT="0"
+LICENSE="GPL-2 LGPL-2.1"
+KEYWORDS="amd64 ~hppa ppc ppc64 ~sparc x86"
+IUSE="dia gnome inkjar lcms mmx nls postscript spell wmf"
+RESTRICT="test"
+
+COMMON_DEPEND="
+	>=virtual/poppler-glib-0.8.3[cairo]
+	dev-cpp/glibmm
+	>=dev-cpp/gtkmm-2.10.0
+	>=dev-libs/boehm-gc-6.4
+	>=dev-libs/glib-2.6.5
+	>=dev-libs/libsigc++-2.0.12
+	>=dev-libs/libxml2-2.6.20
+	>=dev-libs/libxslt-1.0.15
+	dev-libs/popt
+	dev-python/lxml
+	media-gfx/imagemagick
+	media-libs/fontconfig
+	>=media-libs/freetype-2
+	>=media-libs/libpng-1.2
+	>=media-libs/libwpg-0.1
+	sci-libs/gsl
+	x11-libs/libXft
+	>=x11-libs/gtk+-2.10.7
+	>=x11-libs/pango-1.4.0
+	|| ( dev-lang/python[xml] dev-python/pyxml )
+	gnome? ( >=gnome-base/gnome-vfs-2.0 )
+	lcms? ( >=media-libs/lcms-1.14 )
+	spell? (
+		app-text/aspell
+		app-text/gtkspell
+	)"
+
+# These only use executables provided by these packages
+# See share/extensions for more details. inkscape can tell you to
+# install these so we could of course just not depend on those and rely
+# on that.
+RDEPEND="
+	${COMMON_DEPEND}
+	dev-python/numpy
+	dia? ( app-office/dia )
+	postscript? ( >=media-gfx/pstoedit-3.44[plotutils] media-gfx/skencil )
+	wmf? ( media-libs/libwmf )"
+
+DEPEND="${COMMON_DEPEND}
+	dev-libs/boost
+	sys-devel/gettext
+	dev-util/pkgconfig
+	x11-libs/libX11
+	>=dev-util/intltool-0.29"
+
+PATCHES=(
+	"${FILESDIR}/inkscape-0.47-newpoppler.patch"
+)
+
+src_prepare() {
+	base_src_prepare
+	gnome2_src_prepare
+}
+
+pkg_setup() {
+	G2CONF="${G2CONF} --without-perl"
+	G2CONF="${G2CONF} --enable-poppler-cairo"
+	G2CONF="${G2CONF} --with-xft"
+	G2CONF="${G2CONF} $(use_with gnome gnome-vfs)"
+	G2CONF="${G2CONF} $(use_with inkjar)"
+	G2CONF="${G2CONF} $(use_enable lcms)"
+	G2CONF="${G2CONF} $(use_enable mmx)"
+	G2CONF="${G2CONF} $(use_enable nls)"
+	DOCS="AUTHORS ChangeLog NEWS README*"
+}
+
+pkg_postinst() {
+	elog "local configurations (also includes extensions) are moved from"
+	elog "\${HOME}/.inkscape to \${HOME}/.config/inkscape within"
+	elog ">=media-gfx/inkscape-0.47"
+}