X-Git-Url: https://git.pterodactylus.net/?p=overlay.git;a=blobdiff_plain;f=net-irc%2Fxchat%2Fxchat-2.8.8.ebuild;fp=net-irc%2Fxchat%2Fxchat-2.8.8.ebuild;h=dd389261d87347311dba5fe5f5fafbaf10a70057;hp=0000000000000000000000000000000000000000;hb=e536a94402c6f5c2a1861c3be7db2a1d193ddc31;hpb=510d1349eaf5638193f1e85adb91c38621f801ab

diff --git a/net-irc/xchat/xchat-2.8.8.ebuild b/net-irc/xchat/xchat-2.8.8.ebuild
new file mode 100644
index 0000000..dd38926
--- /dev/null
+++ b/net-irc/xchat/xchat-2.8.8.ebuild
@@ -0,0 +1,102 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-irc/xchat/xchat-2.8.8.ebuild,v 1.1 2010/06/01 08:13:55 polynomial-c Exp $
+
+EAPI=2
+
+inherit eutils versionator gnome2 autotools
+
+DESCRIPTION="Graphical IRC client"
+SRC_URI="http://www.xchat.org/files/source/$(get_version_component_range 1-2)/${P}.tar.bz2
+	mirror://sourceforge/${PN}/${P}.tar.bz2
+	xchatdccserver? ( mirror://gentoo/${PN}-dccserver-0.6.patch.bz2 )"
+HOMEPAGE="http://www.xchat.org/"
+
+LICENSE="GPL-2"
+SLOT="2"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="dbus ipv6 libnotify mmx nls ntlm perl python spell ssl tcl xchatnogtk xchatdccserver xft"
+
+RDEPEND=">=dev-libs/glib-2.6.0
+	!xchatnogtk? ( >=x11-libs/gtk+-2.10.0 )
+	ssl? ( >=dev-libs/openssl-0.9.6d )
+	perl? ( >=dev-lang/perl-5.8.0 )
+	python? ( >=dev-lang/python-2.2 )
+	tcl? ( dev-lang/tcl )
+	dbus? ( >=dev-libs/dbus-glib-0.71 )
+	spell? ( app-text/gtkspell )
+	libnotify? ( x11-libs/libnotify )
+	ntlm? ( net-libs/libntlm )
+	!<net-irc/xchat-gnome-0.9"
+
+DEPEND="${RDEPEND}
+	>=dev-util/pkgconfig-0.16
+	nls? ( sys-devel/gettext )"
+
+pkg_setup() {
+	# Added for to fix a sparc seg fault issue by Jason Wever <weeve@gentoo.org>
+	if [[ ${ARCH} = sparc ]] ; then
+		replace-flags "-O[3-9]" "-O2"
+	fi
+}
+
+src_prepare() {
+	use xchatdccserver && epatch "${DISTDIR}"/xchat-dccserver-0.6.patch.bz2
+
+	# use libdir/xchat/plugins as the plugin directory
+	if [ $(get_libdir) != "lib" ] ; then
+		sed -i -e 's:${prefix}/lib/xchat:${libdir}/xchat:' \
+			"${S}"/configure.in || die
+	fi
+
+	epatch "${FILESDIR}"/xchat-2.8.6-nickcompletion_without_space.diff
+
+	# xchat sourcecode ships with po/Makefile.in.in from gettext-0.17
+	# which fails with >=gettext-0.18
+	cp /usr/share/gettext/po/Makefile.in.in "${S}"/po/ || die
+
+	eautoreconf
+}
+
+src_configure() {
+	# xchat's configure script uses sys.path to find library path
+	# instead of python-config (#25943)
+	unset PYTHONPATH
+
+	econf \
+		--enable-shm \
+		$(use_enable dbus) \
+		$(use_enable ipv6) \
+		$(use_enable mmx) \
+		$(use_enable nls) \
+		$(use_enable ntlm) \
+		$(use_enable perl) \
+		$(use_enable python) \
+		$(use_enable spell spell gtkspell) \
+		$(use_enable ssl openssl) \
+		$(use_enable tcl) \
+		$(use_enable !xchatnogtk gtkfe) \
+		$(use_enable xft)
+}
+
+src_install() {
+	USE_DESTDIR=1 gnome2_src_install || die "make install failed"
+
+	# install plugin development header
+	insinto /usr/include/xchat
+	doins src/common/xchat-plugin.h || die "doins failed"
+
+	dodoc ChangeLog README* || die "dodoc failed"
+}
+
+pkg_postinst() {
+	elog
+	elog "XChat binary has been renamed from xchat-2 to xchat."
+	elog
+
+	if has_version net-irc/xchat-systray
+	then
+		elog "XChat now includes it's own systray icon, you may want to remove net-irc/xchat-systray."
+		elog
+	fi
+}