Add kde-base/kmail-4.3.1.

[overlay.git] / kde-base / kmail / kmail-4.3.1.ebuild

diff --git a/kde-base/kmail/kmail-4.3.1.ebuild b/kde-base/kmail/kmail-4.3.1.ebuild
new file mode 100644 (file)
index 0000000..b2aa9a4
--- /dev/null
+++ b/kde-base/kmail/kmail-4.3.1.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/kde-base/kmail/kmail-4.3.1.ebuild,v 1.1 2009/09/01 15:37:02 tampakrap Exp $
+
+EAPI="2"
+
+KMNAME="kdepim"
+inherit kde4-meta
+
+DESCRIPTION="KMail is the email component of Kontact, the integrated personal information manager of KDE."
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~x86"
+IUSE="debug +handbook +semantic-desktop"
+
+DEPEND="
+       >=kde-base/kdelibs-${PV}:${SLOT}[kdeprefix=,semantic-desktop?]
+       >=kde-base/libkdepim-${PV}:${SLOT}[kdeprefix=]
+       >=kde-base/libkleo-${PV}:${SLOT}[kdeprefix=]
+       >=kde-base/libkpgp-${PV}:${SLOT}[kdeprefix=]
+       >=kde-base/libksieve-${PV}:${SLOT}[kdeprefix=]
+       >=kde-base/mimelib-${PV}:${SLOT}[kdeprefix=]
+"
+RDEPEND="${DEPEND}
+       >=kde-base/kmailcvt-${PV}:${SLOT}[kdeprefix=]
+       semantic-desktop? ( >=kde-base/nepomuk-${PV}:${SLOT}[kdeprefix=] )
+"
+
+KMEXTRACTONLY="
+       kaddressbook/org.kde.KAddressbook.Core.xml
+       korganizer/org.kde.Korganizer.Calendar.xml
+       libkleo
+       libkpgp
+       libksieve
+       mimelib
+"
+KMEXTRA="
+       ksendemail/
+       plugins/kmail/
+"
+KMLOADLIBS="libkdepim"
+
+PATCHES=( "${FILESDIR}/${PN}-4.1.72-fix.patch" "${FILESDIR}/remove-trust-requirement-for-encryption.patch" )
+
+src_configure() {
+       mycmakeargs="${mycmakeargs}
+               $(cmake-utils_use_with semantic-desktop Nepomuk)"
+
+       kde4-meta_src_configure
+}
+
+src_compile() {
+       # Bug #276377: kontact/ can build before kmail/, causing a dependency not to be built
+       # Upstream as KDE Bug #198807
+       # (setting via MAKEOPTS to trigger a repoman warning)
+       MAKEOPTS="${MAKEOPTS} -j1"
+       kde4-meta_src_compile
+}
+
+pkg_postinst() {
+       kde4-meta_pkg_postinst
+
+       if ! has_version kde-base/kdepim-kresources:${SLOT}; then
+               echo
+               elog "For groupware functionality, please install kde-base/kdepim-kresources:${SLOT}"
+               echo
+       fi
+}