synfig-core/trunk/configure.ac

   1 # $Id$
   2
   3 # -- I N I T --------------------------------------------------
   4
   5 AC_INIT([Synfig Core],[0.61.08],[http://synfig.org/Bugs],[synfig])
   6 AC_REVISION
   7
   8 AC_CONFIG_AUX_DIR(config)
   9 AC_CONFIG_HEADERS([config.h])
  10 AC_CANONICAL_HOST
  11 dnl AC_CANONICAL_TARGET
  12
  13 AM_INIT_AUTOMAKE([nostdinc])
  14 AM_MAINTAINER_MODE
  15
  16 AC_LIBLTDL_CONVENIENCE
  17 AC_SUBST(INCLTDL)
  18 AC_SUBST(LIBLTDL)
  19
  20 API_VERSION=0.0
  21
  22
  23 AC_DEFINE(LT_SCOPE,[extern],[LibLTDL is linked staticly])
  24
  25
  26
  27
  28 # -- V A R I A B L E S ----------------------------------------
  29
  30 SVN_REPOSITORY=http://svn.voria.com/code/synfig-core
  31 AC_SUBST(SVN_REPOSITORY)
  32
  33 # -- P R O G R A M S ------------------------------------------
  34
  35 AC_PROG_CC
  36 AC_GNU_SOURCE
  37 AC_PROG_CXX
  38 AC_PROG_CPP
  39 AC_PROG_CXXCPP
  40 AC_PROG_INSTALL
  41
  42 AC_LANG([C++])
  43
  44
  45 # -- A R G U M E N T S ----------------------------------------
  46
  47
  48 AC_ARG_DEBUG
  49 AC_ARG_OPTIMIZATION
  50 AC_ARG_WARNINGS
  51 AC_ARG_PROFILING
  52 AC_ARG_PROFILE_ARCS
  53 AC_ARG_BRANCH_PROBABILITIES
  54
  55 AC_ARG_ENABLE(g5opt,[
  56   --enable-g5opt           enable optimizations specific to G5 proc],[
  57 #       CXXFLAGS="$CXXFLAGS -fastf -fPIC"
  58 #       CFLAGS="$CFLAGS -fastf -fPIC"
  59         CXXFLAGS="$CXXFLAGS -mtune=G5 -falign-loops=32"
  60         CFLAGS="$CFLAGS -mtune=G5"
  61 ],
  62 [
  63         true
  64 ])
  65
  66 #MINGW_FLAGS="-mno-cygwin"
  67
  68 AC_WIN32_QUIRKS
  69
  70 # If we are in debug mode, use the debugging version of the
  71 # Microsoft Visual C Runtime Library
  72 #if [[ $debug = "yes" ]] ; then {
  73 #       WIN32_DEBUG_LIBRARY="msvcr70d"
  74 #       WIN32_DEBUG_LIBRARY="msvcrtd"
  75 #       LIBTOOL_PATCH_SED="$LIBTOOL_PATCH_SED
  76 #               s/-lmsvcrt/-l$WIN32_DEBUG_LIBRARY/g;
  77 #       ";
  78 #} ; fi
  79
  80 AC_LIBTOOL_WIN32_DLL
  81 AC_LIBTOOL_DLOPEN
  82 AC_DISABLE_STATIC
  83 AC_ENABLE_SHARED
  84 AC_PROG_LIBTOOL
  85 AC_SUBST(LIBTOOL_DEPS)
  86 AC_LIBTOOL_PATCH
  87
  88 #if [[ "$LIBTOOL_PATCH_SED""x" != "x" ]] ; then {
  89 #       printf "Patching libtool... "
  90 #       cat libtool | sed "$LIBTOOL_PATCH_SED" > libtool2
  91 #       rm libtool
  92 #       mv libtool2 libtool
  93 #       chmod +x libtool
  94 #       AC_MSG_RESULT([patched])
  95 #} fi ;
  96
  97
  98 dnl
  99 dnl dynamic linker
 100 dnl
 101 AC_CHECK_LIB(c, dlopen,
 102         DYNAMIC_LD_LIBS="",
 103         AC_CHECK_LIB(
 104                 dl,
 105                 dlopen,
 106         DYNAMIC_LD_LIBS="-ldl",
 107             DYNAMIC_LD_LIBS=""
 108         )
 109 )
 110
 111 AC_SUBST(DYNAMIC_LD_LIBS)
 112
 113 AC_ARG_ENABLE(half,[
 114   --enable-half           Use OpenEXR's "half" type for color],[
 115         use_openexr_half=$enableval
 116 ],
 117 [
 118         use_openexr_half="no"
 119 ])
 120
 121
 122
 123 AC_ARG_ENABLE(layer-profiling,[
 124   --enable-layer-profiling       Enable layer profiling],[
 125         use_layerprofiling=$enableval
 126 ],
 127 [
 128         use_layerprofiling="no"
 129 ])
 130 if test $use_layerprofiling = "yes" ; then {
 131         AC_DEFINE(SYNFIG_PROFILE_LAYERS,[1],[enable layer profiling])
 132 } ; fi
 133
 134
 135
 136
 137 AC_ARG_WITH(imagemagick,[
 138   --without-imagemagick   Disable support for ImageMagick],[
 139 ],[
 140     AC_CHECK_PROG([imagemagick_convert],[convert],[yes],[no])
 141     with_imagemagick=$imagemagick_convert
 142 ])
 143 if test $with_imagemagick = "no" ; then {
 144         AM_CONDITIONAL(WITH_IMAGEMAGICK,false)
 145 } else {
 146         AM_CONDITIONAL(WITH_IMAGEMAGICK,true)
 147 } ; fi
 148
 149
 150
 151
 152
 153 AC_ARG_WITH(magickpp,[
 154   --without-magickpp        Disable support for Magick++],[
 155 ],[
 156         with_magickpp="yes"
 157 ])
 158 if test $with_magickpp = "yes" ; then {
 159   AC_CHECK_HEADER([Magick++.h],[
 160         MAGICKPP_LIBS="-lMagick++"
 161         AC_DEFINE(HAVE_MAGICKPP,[], [ Define if Magick++ library is available ] )
 162         AC_SUBST(MAGICKPP_LIBS)
 163         AM_CONDITIONAL(HAVE_LIBMAGICKPP,true)
 164         AC_CHECK_LIB(Magick,OptimizeImageTransparency,[
 165                 AC_DEFINE(HAVE_MAGICK_OPTIMIZE,[], [ Define if Magick++ defines OptimizeImageTransparency() ] )
 166                 AM_CONDITIONAL(HAVE_MAGICK_OPTIMIZE,true)
 167         ],[
 168                 AC_MSG_RESULT([ *** OptimizeImageTransparency() not available - need ImageMagick 6.3 or newer ])
 169                 AM_CONDITIONAL(HAVE_MAGICK_OPTIMIZE,false)
 170         ])
 171   ],[
 172         with_magickpp="no"
 173         AC_MSG_RESULT([ *** Magick++ Output target disabled])
 174         TARGET_MAGICKPP="no"
 175         AM_CONDITIONAL(HAVE_LIBMAGICKPP,false)
 176         AM_CONDITIONAL(HAVE_MAGICK_OPTIMIZE,false)
 177   ])
 178 } else {
 179         AM_CONDITIONAL(HAVE_LIBMAGICKPP,false)
 180         AM_CONDITIONAL(HAVE_MAGICK_OPTIMIZE,false)
 181 } ; fi
 182
 183
 184
 185
 186 AC_ARG_WITH(ffmpeg,[
 187   --without-ffmpeg        Disable support for FFMPEG],[
 188 ],[
 189         with_ffmpeg="yes"
 190 ])
 191 if test $with_ffmpeg = "no" ; then {
 192         AM_CONDITIONAL(WITH_FFMPEG,false)
 193 } else {
 194         AM_CONDITIONAL(WITH_FFMPEG,true)
 195 } ; fi
 196
 197
 198
 199
 200 AC_ARG_WITH(vimage,[
 201   --with-vimage        Enable support for apple vImage],[
 202 ],[
 203         with_vimage="no"
 204 ])
 205 if test $with_vimage = "no" ; then {
 206         AM_CONDITIONAL(WITH_VIMAGE,false)
 207 } else {
 208         AM_CONDITIONAL(WITH_VIMAGE,true)
 209         AC_DEFINE(HAS_VIMAGE,[1],[enable apple vImage])
 210         VIMAGE_LIBS="-Wc,-framework -Wc,Accelerate"
 211
 212 } ; fi
 213
 214
 215
 216 AC_ARG_WITH(libdv,[
 217   --without-libdv         Disable support for libdv],[
 218 ],[
 219         with_libdv="yes"
 220 ])
 221 if test $with_libdv = "no" ; then {
 222         AM_CONDITIONAL(WITH_LIBDV,false)
 223 } else {
 224         AM_CONDITIONAL(WITH_LIBDV,true)
 225 } ; fi
 226
 227
 228
 229
 230 # LIBAVCODEC CHECK--------------------
 231
 232 AC_ARG_WITH(libavcodec,[
 233   --without-libavcodec         disable support for libavcodec (Default=auto)],[
 234 ],[
 235         with_libavcodec="yes"
 236 ])
 237
 238 if test $with_libavcodec != "no" ; then {
 239         PKG_CHECK_MODULES(LIBAVCODEC, [libavcodec libavformat],[],[echo no; with_libavcodec="no"])
 240 } ; fi
 241 if test $with_libavcodec = "yes" ; then {
 242         AC_DEFINE(WITH_LIBAVCODEC,[],[enable libavcodec support])
 243         AM_CONDITIONAL(WITH_LIBAVCODEC,true)
 244 } else {
 245         AM_CONDITIONAL(WITH_LIBAVCODEC,false)
 246 } ; fi
 247
 248
 249 if test $with_libavcodec = "yes" ; then {
 250
 251         # Need to check both the new and old locations for the avformat header
 252         # Need to save flags, add avformat flags, check headers and restore flags
 253         ac_save_CPPFLAGS="$CPPFLAGS"
 254         ac_save_CFLAGS="$CFLAGS"
 255         CPPFLAGS="${CPPFLAGS} ${LIBAVCODEC_CFLAGS}"
 256         CFLAGS="${CFLAGS} ${LIBAVCODEC_CFLAGS}"
 257         AC_CHECK_HEADERS(libavformat/avformat.h avformat.h ffmpeg/avformat.h)
 258         CPPFLAGS="${ac_save_CPPFLAGS}"
 259         CFLAGS="${ac_save_CFLAGS}"
 260
 261         AC_ARG_WITH(libswscale,
 262                 [AS_HELP_STRING([--without-libswscale],
 263                         [disable support for libswscale (Default=auto)])],
 264                 [],
 265                 [with_libswscale="yes"]
 266         )
 267
 268         if test $with_libswscale != "no" ; then {
 269                 PKG_CHECK_MODULES(LIBSWSCALE, [libswscale], [], [echo no; with_libswscale="no"])
 270         } ; fi
 271
 272         if test $with_libswscale = "yes" ; then {
 273                 AC_DEFINE(WITH_LIBSWSCALE, [], [enable libswscale support])
 274
 275                 # Need to check both the new and old locations for the swscale header
 276                 # Need to save flags, add swscale flags, check headers and restore flags
 277                 ac_save_CPPFLAGS="$CPPFLAGS"
 278                 ac_save_CFLAGS="$CFLAGS"
 279                 CPPFLAGS="${CPPFLAGS} ${LIBSWSCALE_CFLAGS}"
 280                 CFLAGS="${CFLAGS} ${LIBSWSCALE_CFLAGS}"
 281                 AC_CHECK_HEADERS(libswscale/swscale.h swscale.h ffmpeg/swscale.h)
 282                 CPPFLAGS="${ac_save_CPPFLAGS}"
 283                 CFLAGS="${ac_save_CFLAGS}"
 284         } else {
 285                 AC_CHECK_LIB(avcodec, img_convert,
 286                         [AC_MSG_RESULT([ *** Using deprecated function img_convert.])],
 287                         [AC_MSG_FAILURE([Neither libswscale nor function img_convert was found.])],
 288                         []
 289                 )
 290         } ; fi
 291 } ; fi
 292 AM_CONDITIONAL(WITH_LIBSWSCALE, test "x$with_libswscale" = "xyes")
 293
 294
 295 # FREETYPE2 CHECK--------------------
 296
 297 AC_ARG_WITH(freetype,[
 298   --without-freetype         disable support for freetype (Default=auto)],[
 299 ],[
 300         with_freetype="yes"
 301 ])
 302
 303 if test $with_freetype != "no" ; then {
 304         PKG_CHECK_MODULES(FREETYPE, freetype2,[
 305                 with_freetype="yes"
 306         ],[
 307                 PKG_CHECK_MODULES(FREETYPE, xft,[
 308                         with_freetype="yes"
 309                 ],[
 310                         with_freetype="no"
 311                 ])
 312         ])
 313 } ; fi
 314
 315 if test $with_freetype = "no" ; then {
 316         AM_CONDITIONAL(WITH_FREETYPE,false)
 317 } else {
 318         AM_CONDITIONAL(WITH_FREETYPE,true)
 319 } ; fi
 320
 321
 322 # FONTCONFIG CHECK--------------------
 323
 324 AC_ARG_WITH(fontconfig,[
 325   --without-fontconfig         disable support for fontconfig (Default=auto)],[
 326 ],[
 327         with_fontconfig="yes"
 328 ])
 329
 330 if test $with_fontconfig != "no" ; then {
 331         PKG_CHECK_MODULES(FONTCONFIG, fontconfig,[
 332                 with_fontconfig="yes"
 333         ],[
 334                 with_fontconfig="no"
 335         ])
 336 } ; fi
 337
 338 if test $with_fontconfig = "yes" ; then {
 339         AC_DEFINE(WITH_FONTCONFIG,[],[enable fontconfig support])
 340         AM_CONDITIONAL(WITH_FONTCONFIG,true)
 341 } else {
 342         AM_CONDITIONAL(WITH_FONTCONFIG,false)
 343 } ; fi
 344
 345
 346 # OPENEXR CHECK------------------------
 347 AC_ARG_WITH(openexr,[
 348   --without-openexr        Disable support for ILM's OpenEXR],[
 349 ],[
 350         with_openexr="yes"
 351 ])
 352 if test $with_openexr = "yes" ; then {
 353         PKG_CHECK_MODULES(OPENEXR, OpenEXR,[
 354                 AC_DEFINE(HAVE_OPENEXR,[], [ Define if OpenEXR is available ] )
 355                 AM_CONDITIONAL(WITH_OPENEXR,true)
 356         ],
 357         [
 358                 with_openexr="no"
 359         ])
 360 } ; fi
 361 if test $with_openexr = "no" ; then {
 362         AM_CONDITIONAL(WITH_OPENEXR,false)
 363         use_openexr_half="no"
 364 } ; fi
 365 if test $use_openexr_half = yes ; then {
 366         AC_MSG_RESULT([ ** Using OpenEXR Half.])
 367         CONFIG_DEPS="$CONFIG_DEPS OpenEXR"
 368         CONFIG_CFLAGS="$CONFIG_CFLAGS -DUSE_HALF_TYPE"
 369         OPENEXR_HALF_LIBS="-lHalf"
 370 } else {
 371         OPENEXR_HALF_LIBS=""
 372 } ; fi
 373
 374
 375
 376
 377
 378 # -- L I B R A R I E S ----------------------------------------
 379
 380 AC_LIB_LTDL
 381
 382 ALL_LINGUAS="es fr"
 383 AM_GNU_GETTEXT([external])
 384 # This is here so autoreconf will run autopoint
 385 AM_GNU_GETTEXT_VERSION([0.14.4])
 386 localedir="$datadir/locale"
 387
 388 PKG_CHECK_MODULES(ETL, [ETL >= 0.04.11],,[
 389         AC_MSG_ERROR([ ** You need to install the ETL (version 0.04.11 or greater).])
 390 ])
 391 CONFIG_DEPS="$CONFIG_DEPS ETL"
 392
 393
 394 PKG_CHECK_MODULES(LIBXMLPP, libxml++-2.6,[
 395         CONFIG_DEPS="$CONFIG_DEPS libxml++-2.6"
 396 ],[
 397         PKG_CHECK_MODULES(LIBXMLPP, libxml++-1.0,[
 398                 CONFIG_DEPS="$CONFIG_DEPS libxml++-1.0"
 399         ],[
 400                 AC_MSG_ERROR([ ** You need to install libxml++, either verison 2.6 or 1.0.])
 401         ])
 402 ])
 403
 404 PKG_CHECK_MODULES(LIBSIGC, [sigc++-2.0],,[
 405         AC_MSG_ERROR([ ** libsigc++-2.0 not found. It is required. You should really install it.])
 406 dnl     PKG_CHECK_MODULES(LIBSIGC, [sigc++-1.2],,[
 407 dnl             AC_MSG_ERROR([ ** At least libsigc++-1.2 is required.])
 408 dnl     ])
 409 ])
 410 CONFIG_DEPS="$CONFIG_DEPS sigc++-2.0"
 411
 412 dnl PKG_CHECK_MODULES(GLIB, glib-2.0,[GLIB="yes"],[GLIB="no"])
 413
 414
 415
 416
 417
 418 TARGET_PNG="yes"
 419 TARGET_MNG="yes"
 420 TARGET_JPEG="yes"
 421
 422 AC_CHECK_LIB(png, png_write_row,[
 423         PNG_LIBS="-lpng"
 424         AC_DEFINE(HAVE_LIBPNG,[], [ Define if PNG library is available ] )
 425         AC_SUBST(PNG_LIBS)
 426         AM_CONDITIONAL(HAVE_LIBPNG,true)
 427 ],[
 428         AC_CHECK_LIB(png12, png_write_row,[
 429         PNG_LIBS="-lpng12"
 430         AC_DEFINE(HAVE_LIBPNG,[])
 431         AC_SUBST(PNG_LIBS)
 432         AM_CONDITIONAL(HAVE_LIBPNG,true)
 433         ],[
 434                 AC_MSG_RESULT([ *** PNG Output target disabled])
 435                 TARGET_PNG="no"
 436                 AM_CONDITIONAL(HAVE_LIBPNG,false)
 437         ],[-lz -L${exec_prefix}/lib])
 438 ],[-lz -L${exec_prefix}/lib])
 439
 440 AC_CHECK_LIB(mng, mng_initialize,[
 441         MNG_LIBS="-lmng -lz"
 442         AC_DEFINE(HAVE_LIBMNG,[], [ Define if MNG library is available ] )
 443         AC_SUBST(MNG_LIBS)
 444         AM_CONDITIONAL(HAVE_LIBMNG,true)
 445 ],[
 446         AC_MSG_RESULT([ *** MNG Output target disabled])
 447         TARGET_MNG="no"
 448         AM_CONDITIONAL(HAVE_LIBMNG,false)
 449 ],[-lz -L${exec_prefix}/lib])
 450
 451 AC_CHECK_LIB(jpeg, jpeg_CreateCompress,[
 452         JPEG_LIBS="-ljpeg"
 453         AC_DEFINE(HAVE_LIBJPEG,[], [ Define if JPEG library is available ] )
 454         AC_SUBST(JPEG_LIBS)
 455         AM_CONDITIONAL(HAVE_LIBJPEG,true)
 456 ],[
 457         AC_MSG_RESULT([ *** JPEG Output target disabled])
 458         TARGET_JPEG="no"
 459         AM_CONDITIONAL(HAVE_LIBJPEG,false)
 460 ],[-L${exec_prefix}/lib])
 461
 462
 463 dnl AC_CHECK_HEADERS(jpeglib.h,[],[
 464 dnl     AC_MSG_RESULT([ *** JPEG Output target disabled])
 465 dnl     TARGET_JPEG="no"
 466 dnl     AM_CONDITIONAL(HAVE_LIBJPEG,false)
 467 dnl ])
 468
 469
 470
 471 MODULE_DIR='${libdir}/synfig/modules'
 472 moduledir=$libdir/synfig/modules
 473 AC_SUBST(MODULE_DIR)
 474 SYNFIGLIB_DIR=$libdir/synfig
 475 AC_SUBST(SYNFIGLIB_DIR)
 476
 477 # Check for unordered_map or hash_map headers
 478 AC_MSG_CHECKING([for unordered_map<int,int>::const_iterator])
 479 AC_COMPILE_IFELSE([
 480         AC_LANG_PROGRAM([
 481                 [#include <tr1/unordered_map>]
 482         ],[
 483                 [std::tr1::unordered_map<int,int>::const_iterator iter;]
 484         ])],[
 485         AC_MSG_RESULT([yes])
 486         AC_DEFINE([HASH_MAP_CLASS],[HASH_MAP_NAMESPACE::unordered_map],[The template name for unordered maps.])
 487         AC_DEFINE([HASH_MAP_H],[<tr1/unordered_map>],[The header file to include for unordered maps.])
 488         AC_DEFINE([HASH_MAP_NAMESPACE],[std::tr1],[The namespace for unordered maps.])
 489         AC_DEFINE([FUNCTIONAL_H],[<tr1/functional>],[The header file for hash<T>.])
 490         AC_DEFINE([FUNCTIONAL_HASH_ON_STRING],[1],[Define to 1 if hash<T> needs to use T=String rather than T=char* to hash strings.])
 491 ],[
 492         AC_MSG_RESULT([no])
 493         AC_CHECK_HEADERS([ext/hash_map],[
 494                 AC_DEFINE([HASH_MAP_CLASS],[HASH_MAP_NAMESPACE::hash_map],[The template name for unordered maps.])
 495                 AC_DEFINE([HASH_MAP_H],[<ext/hash_map>],[The header file to include for unordered maps.])
 496                 AC_DEFINE([HASH_MAP_NAMESPACE],[__gnu_cxx],[The namespace for unordered maps.])
 497                 AC_DEFINE([FUNCTIONAL_H],[<ext/functional>],[The header file for hash<T>.])
 498         ],[
 499                 AC_MSG_ERROR([C++ compiler does not seem to support unordered containers])
 500         ])
 501 ])
 502
 503 # Check for unordered_set or hash_set headers
 504 AC_MSG_CHECKING([for unordered_set<int,int>::const_iterator])
 505 AC_COMPILE_IFELSE([
 506         AC_LANG_PROGRAM([
 507                 [#include <tr1/unordered_set>]
 508         ],[
 509                 [std::tr1::unordered_set<int,int>::const_iterator iter;]
 510         ])],[
 511         AC_MSG_RESULT([yes])
 512         AC_DEFINE([HASH_SET_CLASS],[HASH_SET_NAMESPACE::unordered_set],[The template name for unordered sets.])
 513         AC_DEFINE([HASH_SET_H],[<tr1/unordered_set>],[The header file to include for unordered sets.])
 514         AC_DEFINE([HASH_SET_NAMESPACE],[std::tr1],[The namespace for unordered sets.])
 515 ],[
 516         AC_MSG_RESULT([no])
 517         AC_CHECK_HEADERS([ext/hash_set],[
 518                 AC_DEFINE([HASH_SET_CLASS],[HASH_SET_NAMESPACE::hash_set],[The template name for unordered sets.])
 519                 AC_DEFINE([HASH_SET_H],[<ext/hash_set>],[The header file to include for unordered sets.])
 520                 AC_DEFINE([HASH_SET_NAMESPACE],[__gnu_cxx],[The namespace for unordered sets.])
 521         ],[
 522                 AC_MSG_ERROR([C++ compiler does not seem to support unordered containers])
 523         ])
 524 ])
 525
 526
 527
 528
 529
 530 AC_CHECK_HEADERS(signal.h termios.h sys/errno.h)
 531
 532
 533 case "$host" in
 534         *mingw* | *cygwin*)
 535                 AM_CONDITIONAL(WIN32_PKG, true)
 536                 AM_CONDITIONAL(MACOSX_PKG, false)
 537         ;;
 538         *darwin*)
 539                 AM_CONDITIONAL(WIN32_PKG, false)
 540                 AM_CONDITIONAL(MACOSX_PKG, true)
 541         ;;
 542         *)
 543                 AM_CONDITIONAL(WIN32_PKG, false)
 544                 AM_CONDITIONAL(MACOSX_PKG, false)
 545         ;;
 546 esac
 547
 548
 549
 550 # -- H E A D E R S --------------------------------------------
 551
 552 AC_HEADER_SYS_WAIT
 553 AC_CHECK_HEADERS([process.h io.h fcntl.h])
 554
 555 # -- T Y P E S & S T R U C T S --------------------------------
 556
 557 # -- F U N C T I O N S ----------------------------------------
 558
 559 dnl AC_CHECK_FUNCS([floor pow sqrt],[],[
 560 dnl     AC_MSG_ERROR([ ** Could not find proper math functions.])
 561 dnl ])
 562
 563 AC_CHECK_FUNCS([fork])
 564 AC_CHECK_FUNCS([kill])
 565 AC_CHECK_FUNCS([pipe])
 566 AC_CHECK_FUNCS([waitpid])
 567
 568 AC_CHECK_FUNCS(
 569         [isnan],
 570         [],
 571         [
 572                 AC_CHECK_FUNCS(
 573                         [_isnan]
 574                 )
 575         ]
 576 )
 577
 578 AC_CHECK_FUNCS(
 579         [isnanf],
 580         [],
 581         [
 582                 AC_CHECK_FUNCS(
 583                         [_isnanf]
 584                 )
 585         ]
 586 )
 587
 588 AC_CHECK_FUNCS(
 589         [floorl],
 590         [],
 591         [
 592                 AC_CHECK_FUNCS(
 593                         [_floorl]
 594                 )
 595         ]
 596 )
 597
 598 AC_CHECK_LIB([pthread],[pthread_create])
 599
 600 # -- O U T P U T ----------------------------------------------
 601
 602 AC_SUBST(CFLAGS)
 603 AC_SUBST(CXXFLAGS)
 604 AC_SUBST(CPPFLAGS)
 605 AC_SUBST(LDFLAGS)
 606
 607 AC_CONFIG_SUBDIRS(libltdl)
 608
 609 CONFIG_LIBS="-lsynfig"
 610 CONFIG_CFLAGS="$CONFIG_CFLAGS"
 611 AC_SUBST(CONFIG_LIBS)
 612 AC_SUBST(CONFIG_CFLAGS)
 613 AC_SUBST(CONFIG_DEPS)
 614 AC_SUBST(ETL_CFLAGS)
 615
 616 SYNFIG_LIBS="$VIMAGE_LIBS $LIBXMLPP_LIBS $ETL_LIBS $LIBSIGC_LIBS $LTLIBINTL"
 617 SYNFIG_CFLAGS="$LIBXMLPP_CFLAGS $ETL_CFLAGS $LIBSIGC_CFLAGS $CONFIG_CFLAGS -DSYNFIG_NO_DEPRECATED -DLOCALEDIR=\\\"$localedir\\\""
 618
 619 CONFIG_CFLAGS="`echo $CONFIG_CFLAGS | sed s/-mno-cygwin//g | sed s/-mwindows//g`"
 620 SYNFIG_CFLAGS="`echo $SYNFIG_CFLAGS | sed s/-mno-cygwin//g | sed s/-mwindows//g`"
 621 SYNFIG_LIBS="`echo $SYNFIG_LIBS | sed s/-mno-cygwin//g | sed s/-mwindows//g`"
 622
 623 AC_SUBST(LIBADD_DL)
 624
 625 AC_SUBST(SYNFIG_LIBS)
 626 AC_SUBST(SYNFIG_CFLAGS)
 627 AC_SUBST(OPENEXR_HALF_LIBS)
 628
 629 AC_SUBST(API_VERSION)
 630
 631 synfigincludedir=$includedir/synfig-$API_VERSION
 632 AC_SUBST(synfigincludedir)
 633
 634 AC_CONFIG_FILES([synfig-config
 635 synfig.pc
 636 doxygen.cfg
 637 Makefile
 638 po/Makefile.in
 639 src/Makefile
 640 src/synfig/Makefile
 641 src/modules/Makefile
 642 src/modules/lyr_freetype/Makefile
 643 src/modules/lyr_std/Makefile
 644 src/modules/mod_bmp/Makefile
 645 src/modules/mod_dv/Makefile
 646 src/modules/mod_ffmpeg/Makefile
 647 src/modules/mod_filter/Makefile
 648 src/modules/mod_geometry/Makefile
 649 src/modules/mod_gif/Makefile
 650 src/modules/mod_gradient/Makefile
 651 src/modules/mod_imagemagick/Makefile
 652 src/modules/mod_jpeg/Makefile
 653 src/modules/mod_libavcodec/Makefile
 654 src/modules/mod_magickpp/Makefile
 655 src/modules/mod_mng/Makefile
 656 src/modules/mod_noise/Makefile
 657 src/modules/mod_openexr/Makefile
 658 src/modules/mod_particle/Makefile
 659 src/modules/mod_png/Makefile
 660 src/modules/mod_ppm/Makefile
 661 src/modules/mod_yuv420p/Makefile
 662 src/tool/Makefile
 663 src/modules/synfig_modules.cfg
 664 examples/walk/Makefile
 665 examples/Makefile
 666 win32inst.nsi
 667 pkg-info/macosx/synfig-core.info
 668 ])
 669 ## src/modules/trgt_mpg/Makefile
 670 ## src/modules/mptr_mplayer/Makefile
 671 AC_OUTPUT
 672
 673 # -- S U M M A R Y --------------------------------------------
 674
 675 echo "
 676 $PACKAGE_NAME v.$VERSION
 677 Configuration Summary
 678 - - - - - -
 679
 680 Install Prefix -------------------> $prefix
 681 Module directory -----------------> $moduledir
 682 Build Platform -------------------> $build
 683 Host Platform --------------------> $host
 684 Arc Profiling --------------------> $profile_arcs
 685 GProf Profiling ------------------> $profiling
 686 Debug Mode -----------------------> $debug ($debug_flags)
 687 Optimization ---------------------> $optimization
 688 PNG output target support --------> $TARGET_PNG
 689 MNG output target support --------> $TARGET_MNG
 690 JPEG output target support -------> $TARGET_JPEG
 691 ETL_CFLAGS -----------------------> $ETL_CFLAGS
 692 FreeType2 ------------------------> $with_freetype
 693 fontconfig -----------------------> $with_fontconfig
 694 libavcodec -----------------------> $with_libavcodec
 695 libswscale -----------------------> $with_libswscale
 696 vImage ---------------------------> $with_vimage
 697 ImageMagick ----------------------> $with_imagemagick
 698 Magick++ -------------------------> $with_magickpp
 699 FFMPEG ---------------------------> $with_ffmpeg
 700 libdv ----------------------------> $with_libdv
 701 OpenEXR --------------------------> $with_openexr
 702 Using OpenEXR's \"half\" type ------> $use_openexr_half
 703
 704 "'$'"CXX -----------------------------> '$CXX'
 705 "'$'"CXXFLAGS ------------------------> '$CXXFLAGS'
 706 "'$'"SYNFIG_LIBS ---------------------> '$SYNFIG_LIBS'
 707 "'$'"LIBXMLPP_LIBS -------------------> '$LIBXMLPP_LIBS'
 708 "'$'"ETL_LIBS ------------------------> '$ETL_LIBS'
 709 "'$'"LIBSIGC_LIBS --------------------> '$LIBSIGC_LIBS'
 710 "'$'"SYNFIG_CFLAGS -------------------> '$SYNFIG_CFLAGS'
 711 "'$'"LIBADD_DL -----------------------> '$LIBADD_DL'
 712 "