synfig-studio/trunk/configure.ac

   1 # $Id$
   2
   3 # -- I N I T --------------------------------------------------
   4
   5 AC_INIT([Synfig Studio],[0.61.07],[http://synfig.org/Bugs],[synfigstudio])
   6 AC_REVISION
   7
   8 AC_CONFIG_AUX_DIR(config)
   9 AM_CONFIG_HEADER(config.h)
  10 AC_CANONICAL_HOST
  11 dnl AC_CANONICAL_TARGET
  12
  13 AM_INIT_AUTOMAKE
  14 AM_MAINTAINER_MODE
  15
  16 API_VERSION=0.0
  17
  18 # -- V A R I A B L E S ----------------------------------------
  19
  20 SVN_REPOSITORY=http://svn.voria.com/code/synfig-studio
  21
  22 # -- P R O G R A M S ------------------------------------------
  23
  24 AC_PROG_CC
  25 AC_GNU_SOURCE
  26 AC_PROG_CXX
  27 AC_PROG_CPP
  28 AC_PROG_CXXCPP
  29 AC_PROG_INSTALL
  30
  31 AC_LANG_CPLUSPLUS
  32
  33
  34 AC_ARG_DEBUG
  35 AC_ARG_OPTIMIZATION
  36 AC_ARG_WARNINGS
  37 AC_ARG_PROFILE_ARCS
  38 AC_ARG_BRANCH_PROBABILITIES
  39 AC_ARG_PROFILING
  40
  41 AC_ARG_ENABLE(g5opt,[
  42   --enable-g5opt           enable optimizations specific to G5 proc],[
  43     G5OPTFLAGS="-mpowerpc-gpopt -mno-multiple -mno-update -mcpu=970  -mtune=970 -falign-loops=16 -falign-functions=16"
  44 ],
  45 [
  46     G5OPTFLAGS=
  47 ])
  48
  49 AC_WIN32_QUIRKS
  50
  51 AC_LIBTOOL_WIN32_DLL
  52 AC_LIBTOOL_DLOPEN
  53 AC_DISABLE_STATIC
  54 AC_ENABLE_SHARED
  55 AC_PROG_LIBTOOL
  56 AC_SUBST(LIBTOOL_DEPS)
  57 AC_LIBTOOL_PATCH
  58
  59 ## FIXME: add i18n for .desktop and other non-compiled files
  60 ## AM_GLIB_GNU_GETTEXT([external])
  61 ## AC_PROG_INTLTOOL(0.11)
  62 ALL_LINGUAS="fr"
  63 AM_GNU_GETTEXT([external])
  64 # This is here so autoreconf will run autopoint
  65 AM_GNU_GETTEXT_VERSION([0.14.4])
  66
  67 case "$host" in
  68         *mingw* | *cygwin*)
  69                 AM_CONDITIONAL(WIN32_PKG, true)
  70                 AM_CONDITIONAL(MACOSX_PKG, false)
  71         ;;
  72         *darwin*)
  73                 AM_CONDITIONAL(WIN32_PKG, false)
  74                 AM_CONDITIONAL(MACOSX_PKG, true)
  75         ;;
  76         *)
  77                 AM_CONDITIONAL(WIN32_PKG, false)
  78                 AM_CONDITIONAL(MACOSX_PKG, false)
  79         ;;
  80 esac
  81 # -- L I B R A R I E S ----------------------------------------
  82
  83 PKG_CHECK_MODULES(GTKMM, gtkmm-2.4 gthread-2.0,[],[
  84         AC_MSG_ERROR([ ** Gtkmm-2.4 Is a required library, aborting.])
  85 ])
  86 AC_SUBST(GTKMM_CFLAGS)
  87 AC_SUBST(GTKMM_LIBS)
  88
  89 PKG_CHECK_MODULES(SYNFIG, [synfig >= 0.61.07] [ETL >= 0.04.10] sigc++-2.0,,[
  90         AC_MSG_ERROR([ ** Unable to set up dependent libraries (synfig >= 0.61.07, ETL >= 0.04.10)])
  91 ])
  92 AC_SUBST(SYNFIG_CFLAGS)
  93 AC_SUBST(SYNFIG_LIBS)
  94
  95 windowsys="gtkmm"
  96 AC_DEFINE(STUDIO_WINSYS_H,"gtkmm/winsys.h",[blah])
  97 AM_CONDITIONAL(WINDOWSYS_GTKMM,true)
  98
  99 AC_ARG_WITH(userdir,[
 100   --with-userdir=(dirname)         Relative path to user directory],[
 101 ],[
 102 case "$host" in
 103         *mingw* | *cygwin*)
 104                 with_userdir="Synfig"
 105         ;;
 106         *darwin*)
 107                 with_userdir="Library/Synfig"
 108         ;;
 109         *)
 110                 with_userdir=".synfig"
 111         ;;
 112 esac
 113 ])
 114 AC_DEFINE_UNQUOTED(SYNFIG_USER_APP_DIR,"$with_userdir",[Synfig User Data Directory])
 115
 116 # --- FMOD CHECK -------------
 117 AC_ARG_WITH(libfmod,[
 118   --with-libfmod         Enable support for FMOD],[
 119 ],[
 120         AC_CHECK_LIB(fmod, FSOUND_Init,[
 121                 with_libfmod="yes"
 122         ],[
 123                 with_libfmod="no"
 124         ])
 125 ])
 126 if test $with_libfmod = "yes" ; then {
 127         AM_CONDITIONAL(WITH_FMOD,true)
 128         FMOD_LIBS="/usr/lib/libfmod.so"
 129         AC_DEFINE(WITH_FMOD,"I'm here damnit",[blah])
 130 } else {
 131         AM_CONDITIONAL(WITH_FMOD,false)
 132         FMOD_LIBS=
 133 } ; fi
 134
 135 # -- H E A D E R S --------------------------------------------
 136
 137 AC_CHECK_HEADERS([unistd.h signal.h fcntl.h])
 138 AC_CHECK_HEADERS([sys/types.h sys/wait.h sys/stat.h sys/time.h sys/resource.h sys/errno.h])
 139
 140 # -- T Y P E S & S T R U C T S --------------------------------
 141
 142 # -- F U N C T I O N S ----------------------------------------
 143
 144 AC_CHECK_FUNCS([fork])
 145 AC_CHECK_FUNCS([kill])
 146 AC_CHECK_FUNCS([pipe])
 147 AC_CHECK_FUNCS([setpriority mkfifo stat])
 148
 149 # -- A R G U M E N T S ----------------------------------------
 150
 151 # -- O U T P U T ----------------------------------------------
 152
 153 AC_SUBST(CFLAGS)
 154 AC_SUBST(CPPFLAGS)
 155 AC_SUBST(CXXFLAGS)
 156 AC_SUBST(LDFLAGS)
 157 AC_SUBST(SVN_REPOSITORY)
 158
 159 AC_SUBST(API_VERSION)
 160
 161 # fmod stuff...
 162 AC_SUBST(FMOD_LIBS)
 163
 164 imageext=png
 165 AC_SUBST(imageext)
 166
 167 imagedir="${datadir}/pixmaps/synfigstudio"
 168 AC_SUBST(imagedir)
 169
 170 AC_OUTPUT(
 171 Makefile
 172 doxygen.cfg
 173 po/Makefile.in
 174 synfigstudio.desktop
 175 synfigstudio.mime
 176 synfigstudio.keys
 177 synfigstudio.xml
 178 synfigstudio-thumbnailer.schemas
 179 src/Makefile
 180 src/gtkmm/Makefile
 181 src/synfigapp/Makefile
 182 images/Makefile
 183 win32inst.nsi
 184 pkg-info/macosx/synfig-studio.info
 185 )
 186
 187 # -- S U M M A R Y --------------------------------------------
 188
 189 echo "
 190 $PACKAGE_NAME v.$VERSION
 191 Configuration Summary
 192 - - - - - -
 193
 194 Install Prefix -------------------> $prefix
 195 Host Platform --------------------> $host
 196 Icon Format ----------------------> $imageext
 197 Debug Mode -----------------------> $debug
 198 Profiling Mode -------------------> $profiling
 199 Optimizations --------------------> $optimization
 200 Window System --------------------> $windowsys
 201 FMOD Enabled ---------------------> $with_libfmod
 202
 203 "'$'"CXX ------------------------------> '$CXX'
 204 "'$'"CXXFLAGS -------------------------> '$CXXFLAGS'
 205 "'$'"LDFLAGS --------------------------> '$LDFLAGS'
 206 "'$'"SYNFIG_CFLAGS ---------------------> '$SYNFIG_CFLAGS'
 207 "'$'"SYNFIG_LIBS -----------------------> '$SYNFIG_LIBS'
 208 "'$'"GTKMM_CFLAGS ---------------------> '$GTKMM_CFLAGS'
 209 "'$'"GTKMM_LIBS -----------------------> '$GTKMM_LIBS'
 210 "