app-cdr/k3b/k3b-1.0.5-r6.ebuild

   1 # Copyright 1999-2009 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: /var/cvsroot/gentoo-x86/app-cdr/k3b/k3b-1.0.5-r6.ebuild,v 1.1 2009/07/26 15:16:34 ssuominen Exp $
   4
   5 EAPI=2
   6 inherit kde eutils multilib
   7
   8 DESCRIPTION="K3b, KDE CD Writing Software"
   9 HOMEPAGE="http://www.k3b.org/"
  10 SRC_URI="mirror://sourceforge/k3b/${P/_}.tar.bz2"
  11
  12 LICENSE="GPL-2"
  13 SLOT="3.5"
  14 KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~x86-fbsd"
  15 IUSE="alsa css dvd dvdr encode emovix ffmpeg flac hal mp3 musepack musicbrainz
  16         sndfile vcd vorbis"
  17
  18 COMMON_DEPEND="!<app-cdr/k3b-1.0.5-r5
  19         media-libs/libsamplerate
  20         media-libs/taglib
  21         media-sound/cdparanoia
  22         alsa? ( media-libs/alsa-lib )
  23         dvd? ( media-libs/libdvdread )
  24         encode? ( media-sound/lame )
  25         ffmpeg? ( >=media-video/ffmpeg-0.5 )
  26         flac? ( media-libs/flac[cxx] )
  27         hal? ( sys-apps/hal )
  28         mp3? ( media-libs/libmad )
  29         musepack? ( media-libs/libmpcdecsv7 )
  30         musicbrainz? ( media-libs/musicbrainz:1 )
  31         sndfile? ( media-libs/libsndfile )
  32         vorbis? ( media-libs/libvorbis )"
  33 RDEPEND="${COMMON_DEPEND}
  34         app-cdr/cdrdao
  35         media-sound/normalize
  36         virtual/cdrtools
  37         dvdr? ( >=app-cdr/dvd+rw-tools-7 )
  38         css? ( media-libs/libdvdcss )
  39         encode? ( media-sound/sox
  40                 media-video/transcode[dvd] )
  41         emovix? ( media-video/emovix )
  42         vcd? ( media-video/vcdimager )"
  43 DEPEND="${COMMON_DEPEND}
  44         dev-util/pkgconfig"
  45
  46 S=${WORKDIR}/${P/_}
  47
  48 need-kde 3.5
  49
  50 PATCHES=(
  51         "${FILESDIR}/${P}-desktop-entry.diff"
  52         "${FILESDIR}/${P}-ffmpeg-0.4.9_p20080326-API.patch"
  53         "${FILESDIR}/${P}-ffmpeg-0.4.9_p20081014-API.patch"
  54         "${FILESDIR}/${P}-transcode-1.1.patch"
  55         "${FILESDIR}/${P}-libmpcdecsv7.patch"
  56         "${FILESDIR}/${P}-conditional_inclusion.patch"
  57 )
  58
  59 I18N="${PN}-i18n-${PV}"
  60
  61 # Supported languages and translated documentation
  62 LANGS="af ar bg br bs ca cs cy da de el en_GB es et eu fa fi fr ga gl he hi hu is it
  63         ja ka lt mk ms nb nds nl nn pa pl pt pt_BR ru rw se sk sr sr@Latn sv ta tr uk
  64         uz zh_CN zh_TW"
  65 for X in ${LANGS}; do
  66         SRC_URI="${SRC_URI} linguas_${X}? ( mirror://sourceforge/k3b/${I18N}.tar.bz2 )"
  67         IUSE="${IUSE} linguas_${X}"
  68 done
  69
  70 src_unpack() {
  71         kde_src_unpack
  72
  73         if [ -d "${WORKDIR}/${I18N}" ]; then
  74                 cd "${WORKDIR}/${I18N}"
  75                 for X in ${LANGS}; do
  76                         use linguas_${X} || rm -rf "${X}"
  77                 done
  78                 rm -f configure
  79         fi
  80         rm -f "${S}"/configure
  81 }
  82
  83 src_configure() {
  84         local myconf="--with-external-libsamplerate
  85                 --without-resmgr
  86                 --without-cdrecord-suid-root
  87                 --without-k3bsetup
  88                 --with-qt-dir=${QTDIR}
  89                 --enable-mt
  90                 --with-qt-libraries=${QTDIR}/$(get_libdir)
  91                 --disable-dependency-tracking
  92                 --without-arts
  93                 $(use_enable debug)
  94                 $(use_with hal)
  95                 $(use_with encode lame)
  96                 $(use_with ffmpeg)
  97                 $(use_with flac)
  98                 $(use_with vorbis oggvorbis)
  99                 $(use_with sndfile)
 100                 $(use_with mp3 libmad)
 101                 $(use_with musepack)
 102                 $(use_with musicbrainz)
 103                 $(use_with dvd libdvdread)
 104                 $(use_with alsa)"
 105
 106         # Build process of K3b
 107         kde_src_configure
 108
 109         # Build process of K3b-i18n
 110         if [[ -d "${WORKDIR}/${I18N}" ]]; then
 111                 myconf="--with-qt-dir=${QTDIR}
 112                         --with-qt-libraries=${QTDIR}/$(get_libdir)
 113                         --disable-dependency-tracking
 114                         --without-arts
 115                         $(use_enable debug)"
 116
 117                 KDE_S="${WORKDIR}/${I18N}"
 118                 kde_src_configure
 119         fi
 120 }
 121
 122 src_compile() {
 123         KDE_S="${S}"
 124         kde_src_compile
 125
 126         if [[ -d "${WORKDIR}/${I18N}" ]]; then
 127                 KDE_S="${WORKDIR}/${I18N}"
 128                 kde_src_compile
 129         fi
 130 }
 131
 132 src_install() {
 133         KDE_S="${S}"
 134         kde_src_install
 135         dodoc FAQ KNOWNBUGS PERMISSIONS || die "dodoc failed"
 136
 137         if [[ -d "${WORKDIR}/${I18N}" ]]; then
 138                 KDE_S="${WORKDIR}/${I18N}"
 139                 kde_src_install
 140         fi
 141 }
 142
 143 pkg_postinst() {
 144         echo
 145         elog "We don't install k3bsetup anymore because Gentoo doesn't need it."
 146         elog "If you get warnings on start-up, uncheck the \"Check system"
 147         elog "configuration\" option in the \"Misc\" settings window."
 148         echo
 149
 150         local group=cdrom
 151         use kernel_linux || group=operator
 152         elog "Make sure you have proper read/write permissions on the cdrom device(s)."
 153         elog "Usually, it is sufficient to be in the ${group} group."
 154         echo
 155 }