app-cdr/k3b/k3b-1.70.0_beta1.ebuild

   1 # Copyright 1999-2010 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: /var/cvsroot/gentoo-x86/app-cdr/k3b/k3b-1.70.0_beta1.ebuild,v 1.1 2010/02/01 09:31:35 ssuominen Exp $
   4
   5 EAPI=2
   6 WEBKIT_REQUIRED=always
   7 inherit kde4-base
   8
   9 DESCRIPTION="The CD/DVD Kreator for KDE"
  10 HOMEPAGE="http://www.k3b.org/"
  11 SRC_URI="mirror://sourceforge/${PN}/${P/_}.tar.bz2"
  12
  13 LICENSE="GPL-2 FDL-1.2"
  14 SLOT="4"
  15 KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
  16 IUSE="debug dvd emovix encode ffmpeg flac mad lame musepack musicbrainz sndfile sox taglib vcd vorbis +wav"
  17
  18 DEPEND=">=kde-base/libkcddb-${KDE_MINIMAL}
  19         media-libs/libsamplerate
  20         >=x11-libs/qt-gui-4.5:4
  21         dvd? ( media-libs/libdvdread )
  22         ffmpeg? ( >=media-video/ffmpeg-0.5 )
  23         flac? ( >=media-libs/flac-1.2[cxx] )
  24         encode? ( lame? ( media-sound/lame ) )
  25         mad? ( media-libs/libmad )
  26         musepack? ( >=media-sound/musepack-tools-444 )
  27         musicbrainz? ( media-libs/musicbrainz:1 )
  28         sndfile? ( media-libs/libsndfile )
  29         taglib? ( >=media-libs/taglib-1.5 )
  30         vorbis? ( media-libs/libvorbis )"
  31 RDEPEND="${DEPEND}
  32         sys-apps/hal
  33         app-cdr/cdrdao
  34         media-sound/cdparanoia
  35         virtual/cdrtools
  36         dvd? ( >=app-cdr/dvd+rw-tools-7
  37                 encode? ( media-video/transcode[dvd] ) )
  38         emovix? ( media-video/emovix )
  39         encode? ( sox? ( media-sound/sox ) )
  40         vcd? ( media-video/vcdimager )"
  41
  42 DOCS="AUTHORS ChangeLog FAQ PERMISSIONS README RELEASE_HOWTO TODO"
  43
  44 S=${WORKDIR}/${P/_*}
  45
  46 PATCHES=(
  47         "${FILESDIR}/${P/_*}-conditional-inclusion.patch"
  48 )
  49
  50 src_prepare() {
  51         kde4-base_src_prepare
  52 }
  53
  54 src_configure() {
  55         mycmakeargs+=( "-DK3B_BUILD_K3BSETUP=OFF"
  56                 $(cmake-utils_use debug K3B_DEBUG)
  57                 $(cmake-utils_use musicbrainz K3B_ENABLE_MUSICBRAINZ)
  58                 $(cmake-utils_use dvd K3B_ENABLE_DVD_RIPPING)
  59                 $(cmake-utils_use taglib K3B_ENABLE_TAGLIB)
  60                 "-DK3B_BUILD_API_DOCS=OFF"
  61                 $(cmake-utils_use ffmpeg K3B_BUILD_FFMPEG_DECODER_PLUGIN)
  62                 $(cmake-utils_use vorbis K3B_BUILD_OGGVORBIS_DECODER_PLUGIN)
  63                 $(cmake-utils_use mad K3B_BUILD_MAD_DECODER_PLUGIN)
  64                 $(cmake-utils_use musepack K3B_BUILD_MUSE_DECODER_PLUGIN)
  65                 $(cmake-utils_use flac K3B_BUILD_FLAC_DECODER_PLUGIN)
  66                 $(cmake-utils_use sndfile K3B_BUILD_SNDFILE_DECODER_PLUGIN)
  67                 $(cmake-utils_use wav K3B_BUILD_WAVE_DECODER_PLUGIN)
  68                 $(cmake-utils_use encode K3B_BUILD_EXTERNAL_ENCODER_PLUGIN)
  69                 "-DWITH_PolkitQt=OFF" )
  70
  71         if use encode; then
  72                 mycmakeargs+=( $(cmake-utils_use vorbis K3B_BUILD_OGGVORBIS_ENCODER_PLUGIN)
  73                         $(cmake-utils_use lame K3B_BUILD_LAME_ENCODER_PLUGIN)
  74                         $(cmake-utils_use sox K3B_BUILD_SOX_ENCODER_PLUGIN) )
  75         fi
  76
  77         kde4-base_src_configure
  78 }
  79
  80 pkg_postinst() {
  81         kde4-base_pkg_postinst
  82
  83         echo
  84         elog "We don't install k3bsetup anymore because Gentoo doesn't need it."
  85         elog "If you get warnings on start-up, uncheck the \"Check system"
  86         elog "configuration\" option in the \"Misc\" settings window."
  87         echo
  88
  89         local group=cdrom
  90         use kernel_linux || group=operator
  91         elog "Make sure you have proper read/write permissions on the cdrom device(s)."
  92         elog "Usually, it is sufficient to be in the ${group} group."
  93         echo
  94 }