app-cdr/k3b/k3b-2.0.1.ebuild

   1 # Copyright 1999-2010 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: /var/cvsroot/gentoo-x86/app-cdr/k3b/k3b-2.0.1.ebuild,v 1.1 2010/08/18 13:41:29 scarabeus Exp $
   4
   5 EAPI=2
   6 WEBKIT_REQUIRED=always
   7 KDE_LINGUAS="ast be bg ca ca@valencia cs csb da de el en_GB eo es et eu fi fr ga
   8 gl he hi hne hr hu is it ja km ko ku lt mai nb nds nl nn oc pa pl pt pt_BR ro ru
   9 se sk sl sv th tr uk zh_CN zh_TW"
  10 inherit kde4-base
  11
  12 DESCRIPTION="The CD/DVD Kreator for KDE"
  13 HOMEPAGE="http://www.k3b.org/"
  14 SRC_URI="mirror://sourceforge/${PN}/${P/_}.tar.bz2"
  15
  16 LICENSE="GPL-2 FDL-1.2"
  17 SLOT="4"
  18 KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
  19 IUSE="debug dvd emovix encode ffmpeg flac mad lame musepack musicbrainz sndfile sox taglib vcd vorbis +wav"
  20
  21 DEPEND=">=kde-base/libkcddb-${KDE_MINIMAL}
  22         media-libs/libsamplerate
  23         dvd? ( media-libs/libdvdread )
  24         ffmpeg? ( >=media-video/ffmpeg-0.5 )
  25         flac? ( >=media-libs/flac-1.2[cxx] )
  26         encode? ( lame? ( media-sound/lame ) )
  27         mad? ( media-libs/libmad )
  28         musepack? ( >=media-sound/musepack-tools-444 )
  29         musicbrainz? ( media-libs/musicbrainz:1 )
  30         sndfile? ( media-libs/libsndfile )
  31         taglib? ( >=media-libs/taglib-1.5 )
  32         vorbis? ( media-libs/libvorbis )"
  33 RDEPEND="${DEPEND}
  34         sys-apps/hal
  35         app-cdr/cdrdao
  36         media-sound/cdparanoia
  37         virtual/cdrtools
  38         dvd? ( >=app-cdr/dvd+rw-tools-7
  39                 encode? ( media-video/transcode[dvd] ) )
  40         emovix? ( media-video/emovix )
  41         encode? ( sox? ( media-sound/sox ) )
  42         vcd? ( media-video/vcdimager )"
  43
  44 DOCS="ChangeLog FAQ PERMISSIONS README RELEASE_HOWTO"
  45
  46 S=${WORKDIR}/${P/_*}
  47
  48 PATCHES=(
  49         "${FILESDIR}/${PN}-1.69.0-conditional-inclusion.patch"
  50 )
  51
  52 src_prepare() {
  53         kde4-base_src_prepare
  54 }
  55
  56 src_configure() {
  57         mycmakeargs+=( "-DK3B_BUILD_K3BSETUP=OFF"
  58                 $(cmake-utils_use debug K3B_DEBUG)
  59                 $(cmake-utils_use musicbrainz K3B_ENABLE_MUSICBRAINZ)
  60                 $(cmake-utils_use dvd K3B_ENABLE_DVD_RIPPING)
  61                 $(cmake-utils_use taglib K3B_ENABLE_TAGLIB)
  62                 "-DK3B_BUILD_API_DOCS=OFF"
  63                 $(cmake-utils_use ffmpeg K3B_BUILD_FFMPEG_DECODER_PLUGIN)
  64                 $(cmake-utils_use vorbis K3B_BUILD_OGGVORBIS_DECODER_PLUGIN)
  65                 $(cmake-utils_use mad K3B_BUILD_MAD_DECODER_PLUGIN)
  66                 $(cmake-utils_use musepack K3B_BUILD_MUSE_DECODER_PLUGIN)
  67                 $(cmake-utils_use flac K3B_BUILD_FLAC_DECODER_PLUGIN)
  68                 $(cmake-utils_use sndfile K3B_BUILD_SNDFILE_DECODER_PLUGIN)
  69                 $(cmake-utils_use wav K3B_BUILD_WAVE_DECODER_PLUGIN)
  70                 $(cmake-utils_use encode K3B_BUILD_EXTERNAL_ENCODER_PLUGIN) )
  71
  72         if use encode; then
  73                 mycmakeargs+=( $(cmake-utils_use vorbis K3B_BUILD_OGGVORBIS_ENCODER_PLUGIN)
  74                         $(cmake-utils_use lame K3B_BUILD_LAME_ENCODER_PLUGIN)
  75                         $(cmake-utils_use sox K3B_BUILD_SOX_ENCODER_PLUGIN) )
  76         fi
  77
  78         kde4-base_src_configure
  79 }
  80
  81 pkg_postinst() {
  82         kde4-base_pkg_postinst
  83
  84         echo
  85         elog "We don't install k3bsetup anymore because Gentoo doesn't need it."
  86         elog "If you get warnings on start-up, uncheck the \"Check system"
  87         elog "configuration\" option in the \"Misc\" settings window."
  88         echo
  89
  90         local group=cdrom
  91         use kernel_linux || group=operator
  92         elog "Make sure you have proper read/write permissions on the cdrom device(s)."
  93         elog "Usually, it is sufficient to be in the ${group} group."
  94         echo
  95 }