dev-db/mysql-workbench/mysql-workbench-5.2.22.ebuild

   1 # Copyright 1999-2010 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: /var/cvsroot/gentoo-x86/dev-db/mysql-workbench/mysql-workbench-5.2.22.ebuild,v 1.1 2010/06/03 06:26:51 graaff Exp $
   4
   5 EAPI="2"
   6 GCONF_DEBUG="no"
   7
   8 inherit gnome2 eutils flag-o-matic autotools
   9
  10 MY_P="${PN}-oss-${PV}"
  11
  12 DESCRIPTION="MySQL Workbench"
  13 HOMEPAGE="http://dev.mysql.com/workbench/"
  14 SRC_URI="mirror://mysql/Downloads/MySQLGUITools/${MY_P}.tar.gz"
  15
  16 LICENSE="GPL-2"
  17 SLOT="0"
  18 KEYWORDS="~amd64 ~x86"
  19 IUSE="debug nls readline static-libs"
  20
  21 RDEPEND=">=x11-libs/gtk+-2.6
  22         dev-libs/glib:2
  23         gnome-base/libglade:2.0
  24         dev-libs/libsigc++:2
  25         dev-libs/boost
  26         >=dev-libs/libxml2-2.6.2
  27         >=dev-cpp/glibmm-2.14
  28         >=dev-cpp/gtkmm-2.14
  29         dev-libs/libzip
  30         >=virtual/mysql-5.1
  31         dev-libs/libpcre
  32         virtual/opengl
  33         >=dev-lang/lua-5.1[deprecated]
  34         gnome-base/libgnome
  35         x11-libs/pango
  36         || ( sys-libs/e2fsprogs-libs
  37                 dev-libs/ossp-uuid )
  38         >=x11-libs/cairo-1.5.12[svg]
  39         dev-python/pexpect
  40         dev-python/paramiko
  41         readline? ( sys-libs/readline )"
  42 DEPEND="${RDEPEND}
  43         >=dev-cpp/ctemplate-0.95
  44         dev-util/pkgconfig"
  45
  46 S="${WORKDIR}"/"${MY_P}"
  47
  48 src_prepare() {
  49         epatch "${FILESDIR}/${PN}-5.2.17-python-libs.patch"
  50         epatch "${FILESDIR}/${PN}-5.2.17-as-needed-modules.patch"
  51         epatch "${FILESDIR}/${PN}-5.2.22-increase-connection-timeout.patch"
  52         eautoreconf
  53 }
  54
  55 src_configure() {
  56         econf \
  57                 $(use_enable nls i18n) \
  58                 $(use_enable readline readline) \
  59                 $(use_enable debug) \
  60                 $(use_enable static-libs static) \
  61                 --with-system-ctemplate
  62 }