dev-lang/go/go-9999.ebuild

   1 # Copyright 1999-2009 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: $
   4
   5 EAPI="2"
   6 inherit elisp-common eutils mercurial toolchain-funcs
   7
   8 DESCRIPTION="The Go Programming Language"
   9 HOMEPAGE="http://golang.org/"
  10 SRC_URI=""
  11 EHG_REPO_URI="https://go.googlecode.com/hg/"
  12 EHG_REVISION="release"
  13
  14 LICENSE="BSD"
  15 SLOT="0"
  16 KEYWORDS="~amd64 ~x86"
  17 IUSE="emacs vim-syntax"
  18
  19 RESTRICT="test"
  20
  21 RDEPEND="sys-devel/gcc"
  22 DEPEND="${RDEPEND}
  23         emacs? ( virtual/emacs )
  24         sys-devel/bison
  25         sys-apps/ed"
  26
  27 S="${WORKDIR}/hg"
  28
  29 ENVFILE="${WORKDIR}/50${PN}"
  30
  31 src_prepare() {
  32         GOBIN="${WORKDIR}/bin"
  33         mkdir -p "${GOBIN}" || die
  34
  35         sed -i \
  36                 -e "/^GOBIN=/s:=.*:=${GOBIN}:" \
  37                 -e "/MAKEFLAGS=/s:=.*:=${MAKEOPTS}:" \
  38                 src/make.bash || die
  39
  40         sed -i \
  41                 -e "/^CFLAGS=/s:-O2:${CFLAGS}:" \
  42                 src/Make.conf || die
  43
  44         case ${ARCH} in
  45         x86)
  46                 GOARCH="386"
  47                 ;;
  48         *)
  49                 GOARCH="${ARCH}"
  50                 ;;
  51         esac
  52
  53         case ${CHOST} in
  54         *-darwin*)
  55                 GOOS="darwin"
  56                 ;;
  57         *)
  58                 GOOS="linux"
  59                 ;;
  60         esac
  61 #       *-nacl*)
  62 #               GOOS="nacl"
  63 #               ;;
  64
  65         cat > "${ENVFILE}" <<EOF
  66 GOROOT="/usr/$(get_libdir)/${PN}"
  67 GOARCH="${GOARCH}"
  68 GOOS="${GOOS}"
  69 EOF
  70         . "${ENVFILE}"
  71
  72         export GOBIN GOROOT GOARCH GOOS
  73 }
  74
  75 src_compile() {
  76         cd src
  77         PATH="${GOBIN}:${PATH}" GOROOT="${S}" CC="$(tc-getCC)" ./make.bash || die
  78         if use emacs ; then
  79                 elisp-compile "${S}"/misc/emacs/*.el || die
  80         fi
  81 }
  82
  83 src_test() {
  84         cd src
  85         PATH="${GOBIN}:${PATH}" GOROOT="${S}" CC="$(tc-getCC)" ./run.bash || die
  86 }
  87
  88 src_install() {
  89         dobin "${GOBIN}"/* || die
  90
  91         insinto "${GOROOT}"
  92         doins -r pkg || die
  93         doins -r doc || die
  94         doins favicon.ico || die
  95
  96         insinto "${GOROOT}/src"
  97         doins src/Make.* || die
  98
  99         insinto "${GOROOT}/lib"
 100         doins -r lib/godoc || die
 101
 102         if use emacs ; then
 103                 elisp-install ${PN} "${S}"/misc/emacs/*.el* || die "elisp-install failed"
 104         fi
 105
 106         if use vim-syntax ; then
 107                 insinto /usr/share/vim/vimfiles/plugin
 108                 doins "${S}"/misc/vim/go.vim || die
 109         fi
 110
 111         doenvd "${ENVFILE}" || die
 112
 113         dodoc AUTHORS CONTRIBUTORS README || die
 114         dohtml -r doc/* || die
 115 }
 116
 117 pkg_postinst() {
 118         elog "please don't forget to source /etc/profile"
 119 }