media-gfx/inkscape/inkscape-0.47.ebuild

   1 # Copyright 1999-2010 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: /var/cvsroot/gentoo-x86/media-gfx/inkscape/inkscape-0.47.ebuild,v 1.7 2010/01/07 18:14:56 josejx Exp $
   4
   5 EAPI=2
   6 inherit base gnome2
   7
   8 MY_P="${P/_/}"
   9 S="${WORKDIR}/${MY_P}"
  10 SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"
  11
  12 DESCRIPTION="A SVG based generic vector-drawing program"
  13 HOMEPAGE="http://www.inkscape.org/"
  14
  15 SLOT="0"
  16 LICENSE="GPL-2 LGPL-2.1"
  17 KEYWORDS="amd64 ~hppa ppc ppc64 ~sparc x86"
  18 IUSE="dia gnome inkjar lcms mmx nls postscript spell wmf"
  19 RESTRICT="test"
  20
  21 COMMON_DEPEND="
  22         >=virtual/poppler-glib-0.8.3[cairo]
  23         dev-cpp/glibmm
  24         >=dev-cpp/gtkmm-2.10.0
  25         >=dev-libs/boehm-gc-6.4
  26         >=dev-libs/glib-2.6.5
  27         >=dev-libs/libsigc++-2.0.12
  28         >=dev-libs/libxml2-2.6.20
  29         >=dev-libs/libxslt-1.0.15
  30         dev-libs/popt
  31         dev-python/lxml
  32         media-gfx/imagemagick
  33         media-libs/fontconfig
  34         >=media-libs/freetype-2
  35         >=media-libs/libpng-1.2
  36         >=media-libs/libwpg-0.1
  37         sci-libs/gsl
  38         x11-libs/libXft
  39         >=x11-libs/gtk+-2.10.7
  40         >=x11-libs/pango-1.4.0
  41         || ( dev-lang/python[xml] dev-python/pyxml )
  42         gnome? ( >=gnome-base/gnome-vfs-2.0 )
  43         lcms? ( >=media-libs/lcms-1.14 )
  44         spell? (
  45                 app-text/aspell
  46                 app-text/gtkspell
  47         )"
  48
  49 # These only use executables provided by these packages
  50 # See share/extensions for more details. inkscape can tell you to
  51 # install these so we could of course just not depend on those and rely
  52 # on that.
  53 RDEPEND="
  54         ${COMMON_DEPEND}
  55         dev-python/numpy
  56         dia? ( app-office/dia )
  57         postscript? ( >=media-gfx/pstoedit-3.44[plotutils] media-gfx/skencil )
  58         wmf? ( media-libs/libwmf )"
  59
  60 DEPEND="${COMMON_DEPEND}
  61         dev-libs/boost
  62         sys-devel/gettext
  63         dev-util/pkgconfig
  64         x11-libs/libX11
  65         >=dev-util/intltool-0.29"
  66
  67 PATCHES=(
  68         "${FILESDIR}/inkscape-0.47-newpoppler.patch"
  69 )
  70
  71 src_prepare() {
  72         base_src_prepare
  73         gnome2_src_prepare
  74 }
  75
  76 pkg_setup() {
  77         G2CONF="${G2CONF} --without-perl"
  78         G2CONF="${G2CONF} --enable-poppler-cairo"
  79         G2CONF="${G2CONF} --with-xft"
  80         G2CONF="${G2CONF} $(use_with gnome gnome-vfs)"
  81         G2CONF="${G2CONF} $(use_with inkjar)"
  82         G2CONF="${G2CONF} $(use_enable lcms)"
  83         G2CONF="${G2CONF} $(use_enable mmx)"
  84         G2CONF="${G2CONF} $(use_enable nls)"
  85         DOCS="AUTHORS ChangeLog NEWS README*"
  86 }
  87
  88 pkg_postinst() {
  89         elog "local configurations (also includes extensions) are moved from"
  90         elog "\${HOME}/.inkscape to \${HOME}/.config/inkscape within"
  91         elog ">=media-gfx/inkscape-0.47"
  92 }